Holt EMA

November 28th, 2010, 05:14 PM

Port to EL with color.

Code

input:    price(close), gmma(40), alpha(20);
vars:    mygamma(gmma), myalpha(alpha), b(0);

if alpha > 1 then myalpha = 2.0/(alpha+1.0) else myalpha = alpha;
if gmma > 1 then mygamma = 2.0/(gmma+1) else mygamma = gmma;

If CurrentBar = 1 then begin
    value1 = price;
    b = 0.0;
end else begin
    value1 = (1-myalpha)*(value1[1] + b[1]) + myalpha*price;
    b = (1-mygamma)*b[1] + mygamma*(value1 - value1[1]);
end;

Plot1( value1, "Rising" );
Plot2( value1, "Falling" );
Plot3( value1, "Neutral" );
Plot4( value1, "HoltEMA", iff(value1=value1[1], GetPlotColor(3), iff(value1>value1[1], GetPlotColor(1), GetPlotColor(2))));
NoPlot(1);
NoPlot(2);
NoPlot(3);

Enjoy,
-C

November 30th, 2010, 08:44 AM

Does someone have the easylanguage/powerlanguage for the collectiveMA indicator? I need this for my Multicharts.
Sheldon

November 30th, 2010, 08:46 AM

tradersheldon

Does someone have the easylanguage/powerlanguage for the collectiveMA indicator? I need this for my Multicharts.
Sheldon

and also this is not an Elite thread, and that indicator is Elite only.

Post here:

BMT Collective MA

Mike, just curious what exactly the futures.io (formerly BMT) Collective MA is? I apologize if this was described elsewhere. I saw it was part of the new Envelope indi but I had never seen it before then. Thanks.

Blz

And if someone else hasn't done it already, I have, I just need to dig it up.

Mike

November 30th, 2010, 08:50 AM

Thank you!

December 1st, 2010, 02:09 PM

Here's a revised version of this indicator. I split out the algorithm into a function so you can call it directly from another indicator. Also, I added two angle values (in degrees) to the indicator to give a visual cue to the slope of the line. See the attached chart.

The function:

Code

input:    price(NumericSeries), gmma(NumericSimple), alpha(NumericSimple);
vars:    mygamma(gmma), myalpha(alpha), b(0);

if alpha > 1 then myalpha = 2.0/(alpha+1.0) else myalpha = alpha;
if gmma > 1 then mygamma = 2.0/(gmma+1) else mygamma = gmma;

If CurrentBar = 1 then begin
    value1 = price;
    b = 0.0;
end else begin
    value1 = (1-myalpha)*(value1[1] + b[1]) + myalpha*price;
    b = (1-mygamma)*b[1] + mygamma*(value1 - value1[1]);
end;

HoltEMA = value1;

The indicator:

Code

input:    price(close), gmma(40), alpha(20), angle1(30), angle2(60);
vars:    mygamma(gmma), myalpha(alpha), b(0), slope(0), debug(1);

value1 = HoltEMA(price, gmma, alpha);

slope = (arctangent((value1-(value1[1]+value1[2])/2)/1.5/(minmove/pricescale)));

condition1 = value1 > value1[1];
condition2 = slope >= angle2;
condition3 = slope >= angle1;
condition4 = slope <= -1*angle2;
condition5 = slope <= -1*angle1;

Plot1( value1, "FastRising" );
Plot2( value1, "Rising" );
Plot3( value1, "Neutral" );
Plot4( value1, "Falling" );
Plot5( value1, "FastFalling" );

value2 = iff(condition2, GetPlotColor(1), iff(condition3, GetPlotColor(2), GetPlotColor(3)));
value3 = iff(condition4, GetPlotColor(5),    iff(condition5, GetPlotColor(4), GetPlotColor(3)));

if debug = 1 then begin
    #beginCmtryOrAlert
        CommentaryCL("  slope: ", slope);
    #End;
end;

Plot6( value1, "HoltEMA", iff(value1 > value1[1], value2, value3));
NoPlot(1);
NoPlot(2);
NoPlot(3); 
NoPlot(4);
NoPlot(5);

Holt EMA

Discussion in EasyLanguage Programming

Holt EMA