ThinkScript help with SchaffTrendCycle

October 19th, 2020, 08:08 AM

Hello Forum,
I need help in doing the following:
- Plot a buy/sell arrow below/above the candle that triggers the following condition:
#1- cross above/below the oversold/overbought line on the SchaffTrendCycle

-Add a buy/sell alert when #1 is met

Code:
input fastLength = 23;
input slowLength = 50;
input KPeriod = 10;
input DPeriod = 3;
input over_bought = 80;
input over_sold = 20;
input neutral_zone = 50;
input averageType = AverageType.EXPONENTIAL;

def macd = MovingAverage(averageType, close, fastLength) - MovingAverage(averageType, close, slowLength);
def fastK1 = FastKCustom(macd, KPeriod);
def fastD1 = MovingAverage(averageType, fastK1, DPeriod);
def fastK2 = FastKCustom(fastD1, KPeriod);
plot STC = MovingAverage(averageType, fastK2, DPeriod);
plot OverBought = over_bought;
plot OverSold = over_sold;
plot Neutral = neutral_zone;
STC.SetDefaultColor(GetColor(8));
OverBought.SetDefaultColor(GetColor(7));
OverSold.SetDefaultColor(GetColor(7));
Neutral.SetDefaultColor(GetColor(7));

October 19th, 2020, 02:22 PM

zentrader618

Hello Forum,
I need help in doing the following:
- Plot a buy/sell arrow below/above the candle that triggers the following condition:
#1- cross above/below the oversold/overbought line on the SchaffTrendCycle

-Add a buy/sell alert when #1 is met

Try this code:
NOTE: you will not be able to see the original "cycle" plot; just the arrows and the alerts.

input fastLength = 23;
input slowLength = 50;
input KPeriod = 10;
input DPeriod = 3;
input over_bought = 80;
input over_sold = 20;
input neutral_zone = 50;
input averageType = AverageType.EXPONENTIAL;

input alerttextOB = "OverBought Exit!";
input alerttextOS = "OverSold Exit!";
input UseAlerts = {false, default true};
input AlertType = {default "BAR", "ONCE", "TICK"};
input AlertSound = {"Bell", "Chimes", default "Ding", "NoSound", "Ring"};

def macd = MovingAverage(averageType, close, fastLength) - MovingAverage(averageType, close, slowLength);
def fastK1 = FastKCustom(macd, KPeriod);
def fastD1 = MovingAverage(averageType, fastK1, DPeriod);
def fastK2 = FastKCustom(fastD1, KPeriod);
plot STC = MovingAverage(averageType, fastK2, DPeriod);
plot OverBought = over_bought;
plot OverSold = over_sold;
plot Neutral = neutral_zone;
STC.SetDefaultColor(GetColor(8));
OverBought.SetDefaultColor(GetColor(7));
OverSold.SetDefaultColor(GetColor(7));
Neutral.SetDefaultColor(GetColor(7));

plot entryS = if STC crosses below over_bought then High else Double.NaN;
plot entryL = if STC crosses above over_sold then Low else Double.NaN;

entryL.SetPaintingStrategy(PaintingStrategy.ARROW_UP);
entryS.SetPaintingStrategy(PaintingStrategy.ARROW_DOWN);

Alert(entryL and UseAlerts, alerttextOS, if AlertType == AlertType.ONCE then Alert.ONCE else if AlertType == AlertType.TICK then Alert.TICK else Alert.BAR, AlertSound);
Alert(entryS and UseAlerts, alerttextOB, if AlertType == AlertType.ONCE then Alert.ONCE else if AlertType == AlertType.TICK then Alert.TICK else Alert.BAR, AlertSound);

ThinkScript help with SchaffTrendCycle

Discussion in Traders Hideout

ThinkScript help with SchaffTrendCycle