// SuperTrend indicator 
inputs: 
ATRLength(3), ATRMult(1), MedLength(2), UpColor(green), DnColor(red); 

variables: 
ATR(0), 
medi(0), 
dn(0), 
up(0), 
trend(1), 
flag(0), 
flagh(0), 
SuperTrend(0), 
downArrow(0),
upArrow(0);

ATR = AvgTrueRange(ATRLength) * ATRMult; 
medi = Median((High+Low)/2, MedLength); 
up = medi + ATR; 
dn = medi - ATR; 

if Close > up[1] then trend = 1 else if Close < dn[1] then trend = -1;

if trend < 0 and trend[1] > 0 then flag=1 else flag=0; 
if trend > 0 and trend[1] < 0 then flagh = 1 else flagh = 0; 

if trend > 0 and dn < dn[1] then dn=dn[1];
if trend < 0 and up > up[1] then up=up[1]; 

if flag = 1 then up = medi + ATR;
if flagh = 1 then dn = medi - ATR; 

if trend = 1 then SuperTrend = dn else SuperTrend = up; 

if flag = 1 then begin
	downArrow = Text_New( Date, Time, High + 300 Point, "S");
	Text_SetColor(downArrow, DnColor);
end;

if flagh = 1 then Begin
	upArrow = Text_New( Date, Time, Low - 300 Point, "B");
	Text_SetColor(upArrow, UpColor);
end;

Plot1(SuperTrend, "SuperTrend");