moving average of RSI in ThinkOrSwim

July 8th, 2015, 05:22 AM

how to create a moving average of RSI in ThinkOrSwim PLEASE

July 8th, 2015, 04:08 PM

Here you go:

declare lower;

input length = 14;
input over_Bought = 70;
input over_Sold = 30;
input price = close;
input averageType = AverageType.WILDERS;
input RSI_smoothing_averageType = AverageType.exponential;
input RSI_smoothing_length = 10;

def NetChgAvg = MovingAverage(averageType, price - price[1], length);
def TotChgAvg = MovingAverage(averageType, AbsValue(price - price[1]), length);
def ChgRatio = if TotChgAvg != 0 then NetChgAvg / TotChgAvg else 0;

def RSI = 50 * (ChgRatio + 1);
plot OverSold = over_Sold;
plot OverBought = over_Bought;

plot RSI_moving_average = MovingAverage(RSI_smoothing_averageType, RSI, RSI_smoothing_length);

RSI_moving_average.DefineColor("OverBought", GetColor(5));
RSI_moving_average.DefineColor("Normal", GetColor(7));
RSI_moving_average.DefineColor("OverSold", GetColor(1));
RSI_moving_average.AssignValueColor(if RSI > over_Bought then RSI_moving_average.color("OverBought") else if RSI < over_Sold then RSI_moving_average.color("OverSold") else RSI_moving_average.color("Normal"));
OverSold.SetDefaultColor(GetColor(8));
OverBought.SetDefaultColor(GetColor(8));

July 9th, 2015, 02:19 PM

Thanks so much, how to I get the code from here to the platform?

July 9th, 2015, 05:04 PM

No worries.

Highlight and copy all the code I supplied. Open ThinkorSwim and go to charts, then click studies-->edit studies. A window will pop up and select "new" in the bottom left corner. A new script window will pop up. Clear out the window of any text code in there and paste the code you copied. You can change the name at the top of the window if you like. Hit "ok" and the indicator is now available.

Keep me posted on how it works for you. If you need any others let me know. I may be able to code it or already may have it coded.
-Jeff

March 5th, 2021, 08:42 PM

Not sure if this is the most appropriate place to ask this question, but stumbled on this thread and am hoping someone can help me create a ThinkorSwim script which will chart RSI with 2 (two) moving averages, rather than just one--a 9 period SMA (shown in green) and 45 period WMA (shown in red), atop the raw RSI (in black). Am happy to pay someone to help me with this if necessary. Many thanks.

March 6th, 2021, 11:31 AM

Let me know if this is what you wanted. I used the TOS RSI code as a starting point and added the averages at the bottom.

Code

declare lower;

input length = 14;
input over_Bought = 70;
input over_Sold = 30;
input price = close;
input averageType = AverageType.WILDERS;
input showBreakoutSignals = no;

def NetChgAvg = MovingAverage(averageType, price - price[1], length);
def TotChgAvg = MovingAverage(averageType, AbsValue(price - price[1]), length);
def ChgRatio = if TotChgAvg != 0 then NetChgAvg / TotChgAvg else 0;

plot RSI = 50 * (ChgRatio + 1);
plot OverSold = over_Sold;
plot OverBought = over_Bought;
plot UpSignal = if RSI crosses above OverSold then OverSold else Double.NaN;
plot DownSignal = if RSI crosses below OverBought then OverBought else Double.NaN;

UpSignal.SetHiding(!showBreakoutSignals);
DownSignal.SetHiding(!showBreakoutSignals);

RSI.DefineColor("OverBought", GetColor(5));
RSI.DefineColor("Normal", GetColor(7));
RSI.DefineColor("OverSold", GetColor(1));
RSI.AssignValueColor(if RSI > over_Bought then RSI.color("OverBought") else if RSI < over_Sold then RSI.color("OverSold") else RSI.color("Normal"));
OverSold.SetDefaultColor(GetColor(8));
OverBought.SetDefaultColor(GetColor(8));
UpSignal.SetDefaultColor(Color.UPTICK);
UpSignal.SetPaintingStrategy(PaintingStrategy.ARROW_UP);
DownSignal.SetDefaultColor(Color.DOWNTICK);
DownSignal.SetPaintingStrategy(PaintingStrategy.ARROW_DOWN);

input average1Type = AverageType.SIMPLE;
input average1Length = 9;
input average2Type = AverageType.WILDERS;
input average2Length = 45;

plot avg1 = MovingAverage(average1Type, RSI, average1Length);
avg1.setDefaultColor(Color.GREEN);
plot avg2 = MovingAverage(average2Type, RSI, average2Length);
avg2.setDefaultColor(Color.RED);

March 6th, 2021, 01:47 PM

Thank you, JayC. Your code works nicely. Wishing you good fortune with your trading.

March 10th, 2021, 05:22 PM

Sometimes I like to overlay a 5 SMA on top of the RSI. The crosses often present some interesting opportunities.

June 28th, 2022, 03:31 AM

Why can't I simply drag and drop the moving average on top of the RSI like it's done on other platform? Why do I even need to code for such a simple task?

moving average of RSI in ThinkOrSwim

Discussion in ThinkOrSwim

moving average of RSI in ThinkOrSwim