Horizontal Moving Average?

October 1st, 2014, 07:10 PM

Hello, I'm trying to plot a horizontal moving average. I'm not sure how to do it. I'd provide an example but I am not allowed to post images or links. Basically I just want it like

------------------------------------------------------- 100.01

rather than the curved up and down moving average.

I have for example

def F10Length = 55;
def F10 = ExpAverage(Price, F10Length);
plot Fib55 = F10;

But it shows up as a curved line. I don't know how to get averages to plot horizontally like the Camarilla Points indicator for example.

To support the forum, I made the following Tick Index indicator.

Code

declare lower;
input Period = 21;

plot TickIndex = close("$TICK");
#You can change the index by changing the symbol between the " ".  
#$TICK = NYSE Index
#$TIKQ = NASDAQ Cumulative Index
#$TIKRL = Russell 2000 Index
#$TIKSP = S&P 500 Index
#$TIKI = DJIA Index
#$TIKUS = All US Stock Index
 
TickIndex.SetPaintingStrategy(PaintingStrategy.HISTOGRAM);
TickIndex.DefineColor("Up", Color.UPTICK);
TickIndex.DefineColor("Down", Color.DOWNTICK);
TickIndex.AssignValueColor(if TickIndex > 0 then TickIndex.color("Up") else if TickIndex < 0 then TickIndex.color("Down") else GetColor(4));
TickIndex.SetLineWeight(3);

def StDev = stdev(data = TickIndex, length = period);
def AvgLine = Average(data = TickIndex, length = period);

def UpperDev = 2.0;
def LowerDev = -2.0;

plot UpperBand = AvgLine + UpperDev * StDev;
Upperband.SetDefaultColor(color.RED);
plot LowerBand = AvgLine + LowerDev * StDev;
LowerBand.SetDefaultColor(color.GREEN);

plot BaseLine = 0;
BaseLine.SetDefaultColor(color.GRAY);
plot Overbought = 800;
Overbought.SetDefaultColor(color.GRAY);
plot Oversold = -800;
Oversold.SetDefaultColor(color.GRAY);

Beats having a separate $TICK chart open. I also added a StDev 2 Bollinger Band and +/-800 lines.

October 1st, 2014, 08:25 PM

You can attach images, just not from external sources.

Search for ADXVMA, it does what you want.

Mike

October 1st, 2014, 09:20 PM

Thank you. I only found 1 result searching this forum and it's not exactly what I was explaining.

I'm trying to get my moving averages to plot horizontally like the picture I attached.

October 19th, 2014, 01:12 PM

try this

#Horizontal Line

input n = 9;

def a = Average(close, n);
def c = HighestAll(if IsNaN(close[-1]) then a else Double.NaN);
plot l = c;
l.SetPaintingStrategy(PaintingStrategy.line);
l.SetLineWeight(1);
l.SetDefaultColor(color.white);

Horizontal Moving Average?

Discussion in ThinkOrSwim

Horizontal Moving Average?