MultiCharts Daily Levels

March 3rd, 2014, 07:06 PM

I am a SC user and trying to use MC. I cannot figure out some simple stuff..... I want to :

1. Automatically plot previous day's hi and lo from PIT session on a globex 5 min chart.

2. I want to plot overnight hi and lo on globex 5 min chart

3. I want to plot open of current pit session on my globex 5 min chart.

Appreciate any help on this.

Wolf

ABCTG · March 4th, 2014, 05:13 AM

Traderwolf,

does the Globex chart include or exclude the Pit session? If it's the latter the best way in my opinion is sending the values from a Pit session chart using EasyLanguage Collections.

Regards,
ABCTG

March 4th, 2014, 07:24 AM

ABCTG

Traderwolf,

does the Globex chart include or exclude the Pit session? If it's the latter the best way in my opinion is sending the values from a Pit session chart using EasyLanguage Collections.

Regards,
ABCTG

The globex chart includes the pit session.

Wolf

ABCTG · March 4th, 2014, 04:33 PM

Wolf,

in this case you can track the values all from one chart. Something basic like the study below does the trick with plots and can serve as a framework. One idea for example would be to use trendlines instead of plots.

Regards,
ABCTG

Code

Inputs:
	PitStartTime		(830),
	PitEndTime		(1515);
	
Variables:
	HavePitSession	(false),
	HavePitReset 		(false),
	HaveGlobexReset	(false),
	DayOpen 		(0),
	PitHigh 		(0),
	PitLow			(0),
	ETHHigh		(0),
	ETHLow			(0),
	GlobexHigh		(-999999),
	GlobexLow		(+999999),
	DayHigh		(-999999),
	DayLow			(+999999);

//reset flags and daily extremes on new day
if Date <> Date[1] then
begin
	HavePitReset = false;
	
	DayHigh = -999999;
	DayLow	= +999999;	
end;


//check for pit session
HavePitSession = false;
HavePitSession = HavePitSession or (Time > PitStartTime and Time <= PitEndTime);


//in pit session track open and session extremes
if HavePitSession then
begin
	if HavePitReset = false then
	begin
		HavePitReset = true;
		
		//store the open
		DayOpen = Open;
		
		//reset globex tracking variables
		GlobexHigh = -999999;
		GlobexLow = +999999;	
	end;
	
	if High > DayHigh then
		DayHigh = High;
	if Low < DayLow then
		DayLow = Low;
		
	PitHigh = DayHigh;
	PitLow = DayLow;
end
//track globex extremes
else
begin
	if High > GlobexHigh then
		GlobexHigh = High;
	
	if Low < GlobexLow then
		GlobexLow = Low;
	
	ETHHigh = GlobexHigh;
	ETHLow = GlobexLow;
end;

//plot values	
if PitHigh <> 0 then Plot1(PitHigh, "Pit High");
if PitLow <> 0 then Plot2(PitLow, "Pit Low");
if DayOpen <> 0 then Plot3(DayOpen, "Pit Open");
if ETHHigh <> 0 then Plot4(ETHHigh, "Globex High");
if ETHLow <> 0 then Plot5(ETHLow, "Globex Low");

March 4th, 2014, 05:33 PM

Thanks!

Wolf

MultiCharts Daily Levels

Discussion in MultiCharts

MultiCharts Daily Levels