{
Perrys Trading Platform, Method 1

https://nexusfi.com/traders-hideout/3514-perrys-trading-platform.html, post #71

ENTRY RULES:

ONLY TRADE IN THE DIRECTION OF THE EMA(20). Never try anything else. This will keep you in the money and sane, with no stress.

Trading Method 1:

Long Entries:

1. The EMA(20) - the coloured line - must be going UP. Colour = BLUE

2. The EMA(5) - the black line - must have gone UP at least 2 Bars or more.

3. The Setup bar LOW must be LESS than or touching the EMA(5) and the Setup bar HIGH must be greater than the EMA(20).

4. From the Setup bar, count 5 bars backwards including the setup bar.

5. ENTER the trade 1 tick/pip above the Highest High of the 5 bars.

6. Confirm that ForceIndex = BLUE


SHORT Entries:

1. The EMA(20) - the coloured line - must be going DOWN. Colour = RED

2. The EMA(5) - the black line - must have gone DOWN at least 2 Bars or more.

3. The Setup bar HIGH must be GREATER than or touching the EMA(5) and the Setup bar LOW must be less than the EMA(20).

4. From the Setup bar, count 5 bars backwards including the setup bar.

5. ENTER the trade 1 tick/pip below the Lowest Low of the 5 bars.

6. Confirm that ForceIndex = RED

To start out I would recommend using a 2 or 3 range chart because your stops can be very small. I would then recommend trading 2 contracts, with a proft target of 4 ticks for the first contract, and a 8 tick profit for the second contract. A total of 12. Your SL can then be 4 ticks. When the first target is reached, put SL to BE less 2 ticks. All this can be put into an ATM strategy. A trade like this can give you $150. A few of these a day can be good trading. Later on if your account grows you can put 4 or 6 contracts, and take less trades.

}

input: adxLength(5), forceLength(13), offset(.003), debug(0);
// set the offset relative to the instrument you are trading.  I.e.  If you trade 6E, then use something like 0.0002, for TF use 0.1
// set debug to 1 to get diagnostic information about the conditions

variables: 
    oDMIPlus( 0 ), 
    oDMIMinus( 0 ), 
    oDMI( 0 ), 
    oADX( 0 ), 
    oADXR( 0 ), 
    oVolty( 0 ) ;
    
value5 = XAverage(close, 5);
value20 = XAverage(close, 20);

// force
value1 = XAverage(((close-close[1])*volume), forceLength);

// adx
value2 = DirMovement( H, L, C, adxLength, oDMIPlus, oDMIMinus, oDMI, oADX, oADXR, 
 oVolty ) ;

// long conditions

// 1. The EMA(20) - the coloured line - must be going UP. Colour = BLUE
condition1 = value20 >= value20[1];
// 2. The EMA(5) - the black line - must have gone UP at least 2 Bars or more.
condition2 = value5 > value5[1] and value5[1] > value5[2];
// 3. The Setup bar LOW must be LESS than or touching the EMA(5) and the Setup bar HIGH must be greater than the EMA(20).
condition3 = low <= value5 and high > value20;
// 4. From the Setup bar, count 5 bars backwards including the setup bar.
// 5. ENTER the trade 1 tick/pip above the Highest High of the 5 bars.
value30 = highest(high,5);
// 6. Confirm that ForceIndex = BLUE
condition4 = value1 > value1[1];
// 7. ADX > +DM or ADX > -DM
condition5 = oadx >= oDMIPlus or oadx >= oDMIMinus; // condition for trend

condition6 = condition1 and condition2 and condition3 and condition4 and condition5;

if debug = 1 then begin
    #beginCmtryOrAlert
        CommentaryCL("Condidition for PTPv1 Long");
        CommentaryCL("  L1: ", Condition1);
        CommentaryCL("  L2: ", Condition2);
        CommentaryCL("  L3: ", Condition3);
        CommentaryCL("  L4: ", Condition4);
        CommentaryCL("  L5: ", Condition5);
        CommentaryCL("enter at: ", value30:2:5);
    #End;
end;

// short condition
// 1. The EMA(20) - the coloured line - must be going DOWN. Colour = RED
condition10 = value20 <= value20[1];
// 2. The EMA(5) - the black line - must have gone DOWN at least 2 Bars or more.
condition11 = value5 < value5[1] and value5[1] < value5[2];
// 3. The Setup bar HIGH must be GREATER than or touching the EMA(5) and the Setup bar LOW must be less than the EMA(20).
condition12 = high >= value5 and low < value20;
// 4. From the Setup bar, count 5 bars backwards including the setup bar.
// 5. ENTER the trade 1 tick/pip below the Lowest Low of the 5 bars.
value31 = lowest(low,5);
// 6. Confirm that ForceIndex = RED
condition13 = value1 < value1[1];
// 7. ADX > +DM or ADX > -DM
condition14 = oadx >= oDMIPlus or oadx >= oDMIMinus;

condition15 = condition10 and condition11 and condition12 and condition13 and condition14;

if debug = 1 then begin
    #beginCmtryOrAlert
           CommentaryCL("Condidition for P1v1 short");
        CommentaryCL("  S1: ", Condition10);
        CommentaryCL("  S2: ", Condition11);
        CommentaryCL("  S3: ", Condition12);
        CommentaryCL("  S4: ", Condition13);
        CommentaryCL("  S5: ", Condition14);
        CommentaryCL("enter at: ", value31:2:5);
    #End;
end;

if condition6 then begin
    Plot1(high + offset, "Long1");
    #beginCmtryOrAlert
        CommentaryCL("Condidition for PTPv1 long is met. Enter at: ", value30:2:5);
    #End;
end else NoPlot(1);
if condition15 then begin
    Plot2(low - offset, "Short1");
    #beginCmtryOrAlert
        CommentaryCL("Condidition for PTPv1 short is met. Enter at: ", value31:2:5);
    #End;
end else NoPlot(2);

{
Perrys Trading Platform, Method #2

https://nexusfi.com/traders-hideout/3514-perrys-trading-platform.html, post #72

ENTRY RULES:

To start out I would recommend using a 2 or 3 range chart because your stops can be very small. I would then 
recommend trading 2 contracts, with a proft target of 4 ticks for the first contract, and 
a 8 tick profit for the second contract. A total of 12. Your SL can then be 4 ticks. When the first 
target is reached, put SL to BE less 2 ticks. All this can be put into an ATM strategy. A trade like 
this can give you $150. A few of these a day can be good trading. Later on if your account grows you 
can put 4 or 6 contracts, and take less trades.

ENTRY RULES:

ONLY TRADE IN THE DIRECTION OF THE EMA(20). Never try anything else. This will keep you in the money and sane, with no stress.

Trading Method 2:

Long Entries:

1. The EMA(20) - the coloured line - must be going UP. Colour = BLUE

2. The EMA(5) - the black line - must have gone DOWN at least 2 Bars or more toward the EMA(20)

3. The Setup bar must be a Green candle.

4. From the Setup bar, count 5 bars backwards including the setup bar.

5. The Lowest High of the last 5 bars including the setup bar must be greater than the EMA(20)

5. ENTER the trade 1 tick/pip above the Setup bar.

6. Confirm that ForceIndex = BLUE


SHORT Entries:

1. The EMA(20) - the coloured line - must be going DOWN. Colour = RED

2. The EMA(5) - the black line - must have gone UP at least 2 Bars or more.

3. The setup bar must be a red candle

4. From the Setup bar, count 5 bars backwards including the setup bar.

5. The Highest Low of the last 5 bars including the setup bar must be less than the EMA(20)

6. ENTER the trade 1 tick/pip below the setup bar

7. Confirm that ForceIndex = RED
}

input: adxLength(5), forceLength(13), offset(0.003), debug(0);
// set the offset relative to the instrument you are trading.  I.e.  If you trade 6E, then use something like 0.0002, for TF use 0.1
// set debug to 1 to get diagnostic information about the conditions

variables: 
    oDMIPlus( 0 ), 
    oDMIMinus( 0 ), 
    oDMI( 0 ), 
    oADX( 0 ), 
    oADXR( 0 ), 
    oVolty( 0 ) ;
    
value5 = XAverage(close, 5);
value20 = XAverage(close, 20);

// force
value1 = XAverage(((close-close[1])*volume), forceLength);

// adx
value2 = DirMovement( H, L, C, adxLength, oDMIPlus, oDMIMinus, oDMI, oADX, oADXR, 
 oVolty ) ;

// long conditions

// 1. The EMA(20) - the coloured line - must be going UP. Colour = BLUE
condition1 = value20 >= value20[1];
// 2. The EMA(5) - the black line - must have gone DOWN at least 2 Bars or more toward the EMA(20)
condition2 = value5 < value5[1] and value5[1] < value5[2];
// 3. The Setup bar must be a Green candle.
condition3 = close > open;
// 4. From the Setup bar, count 5 bars backwards including the setup bar.
// 5. The Lowest High of the last 5 bars including the setup bar must be greater than the EMA(20)
condition4 = lowest(high,5) > value20;
// 5. ENTER the trade 1 tick/pip above the Setup bar.
value30 = high;
// 6. Confirm that ForceIndex = BLUE
condition5 = value1 > value1[1];
// 7. ADX > +DM or ADX > -DM
condition6 = oadx >= oDMIPlus or oadx >= oDMIMinus; // condition for trend

condition7 = condition1 and condition2 and condition3 and condition4 and condition5 and condition6;

if debug = 1 then begin
    #beginCmtryOrAlert
        CommentaryCL("Condidition for PTPv2 Long");
        CommentaryCL("  L1: ", Condition1);
        CommentaryCL("  L2: ", Condition2);
        CommentaryCL("  L3: ", Condition3);
        CommentaryCL("  L4: ", Condition4);
        CommentaryCL("  L5: ", Condition5);
        CommentaryCL("  L6: ", Condition6);
        CommentaryCL("enter at: ", value30:2:5);
    #End;
end;
        
// short condition

// 1. The EMA(20) - the coloured line - must be going DOWN. Colour = RED
condition10 = value20 <= value20[1];
// 2. The EMA(5) - the black line - must have gone UP at least 2 Bars or more.
condition11 = value5 > value5[1] and value5[1] > value5[2];
// 3. The setup bar must be a red candle
condition12 = close < open;
// 4. From the Setup bar, count 5 bars backwards including the setup bar.
// 5. The Highest Low of the last 5 bars including the setup bar must be less than the EMA(20)
condition13 = highest(low, 5) < value20;
// 6. ENTER the trade 1 tick/pip below the setup bar
value31 = low;
// 7. Confirm that ForceIndex = RED
condition14 = value1 < value1[1];
// 7. ADX > +DM or ADX > -DM
condition15 = oadx >= oDMIPlus or oadx >= oDMIMinus;

condition16 = condition10 and condition11 and condition12 and condition13 and condition14 and condition15;

if debug = 1 then begin
    #beginCmtryOrAlert
           CommentaryCL("Condidition for P1v1 short");
        CommentaryCL("  S1: ", Condition10);
        CommentaryCL("  S2: ", Condition11);
        CommentaryCL("  S3: ", Condition12);
        CommentaryCL("  S4: ", Condition13);
        CommentaryCL("  S5: ", Condition14);
        CommentaryCL("  S6: ", Condition15);
        CommentaryCL("enter at: ", value31:2:5);
    #End;
end;


if condition7 then begin
    Plot1(high + offset, "Long2");
    #beginCmtryOrAlert
        CommentaryCL("Condidition for PTPv2 long is met. Enter at: ", value30:2:5);
    #End;
end else NoPlot(1);
if condition16 then begin
    Plot2(low - offset, "Short2");
    #beginCmtryOrAlert
        CommentaryCL("Condidition for PTPv2 short is met. Enter at: ", value31:2:5);
    #End;
end else NoPlot(2);