Help with thinkscript scan code

February 6th, 2021, 12:48 PM

I'm hoping someone can help with this:

I want a scan that scans for 20SMA above 50SMA and 50SMA above 200SMA but allows me to define a percentage that they are within eachother.

I figured it out for the basics no clue how to add percentage conditions in.

I also want to add in price within x% of 20SMA, either above or below.

Here is what I have:

SimpleMovingAvg("length" = 20)."SMA" is greater than or equal to SimpleMovingAvg("length" = 50)."SMA"
and
SimpleMovingAvg("length" = 50)."SMA" is greater than or equal to SimpleMovingAvg("length" = 200)."SMA"

Thanks.

February 7th, 2021, 01:16 AM

I'm guessing you want the difference between the two moving averages to be less than or equal to the specified percentage.

Jay

Code

input pct2050 = 4;
input pct50200 = 10;
input pctPrice = 5;

def sma20 = SimpleMovingAvg(length = 20).SMA;
def sma50 = SimpleMovingAvg(length = 50).SMA;
def sma200 = SimpleMovingAvg(length = 200).SMA;

def diff2050 = sma20/sma50 - 1;
def diff50200 = sma50/sma200 - 1;
def priceTo20 = close/sma20 - 1;

plot result = sma20 >= sma50 and sma50 >= sma200 and
              diff2050 <= (pct2050 / 100) and
              diff50200 <= (pct50200 / 100) and 
              AbsValue(priceTo20) <= (pctPrice / 100);

And here's a separate study to view the current values on the chart...

Code

def diff2050 = sma20/sma50 - 1;
AddLabel(yes, "diff2050: " + AsPercent(diff2050), Color.CYAN);

def diff50200 = sma50/sma200 - 1;
AddLabel(yes, "diff50200: " + AsPercent(diff50200), Color.CYAN);

def priceTo20 = close/sma20 - 1;
AddLabel(yes, "priceTo20: " + AsPercent(priceTo20), Color.CYAN);

Help with thinkscript scan code

Discussion in ThinkOrSwim

Help with thinkscript scan code