Hi guys,

I was wondering how do I color the Fisher Transform bars in TOS like the Fisher Transform Multicolor indicator in Ninjatrader?

Warmest regards
Azrael

Do you know the conditions?
Is it simply above and below, green and red?

Not just that.

Something like:
If the values are rising, plot the up color,
If the values are falling, plot the down color.

Something like this:

You're just trying to assign the value rise and fall color...it looks something like this...

assignvaluecolor(if fish >= fish[1] then color.green else color.red);

Thanks!

I tried doing the script up myself with your code:

I got the colors I wanted but the bars look faint and fuzzy. Any ideas to make them darker or maybe to put an black outline around them?

(If it is not too much trouble, is there a way to set the colors for the bars at will using the studies settings?)

Use this....

declare lower;

input price = hl2;
input length = 10;

def maxHigh = Highest(price, length);
def minLow = Lowest(price, length);
def range = maxHigh - minLow;
def value = if IsNaN(price)
then Double.NaN
else if IsNaN(range)
then value[1]
else if range == 0
then 0
else 0.66 * ((price - minLow) / range - 0.5) + 0.67 * value[1];
def truncValue = if value > 0.99 then 0.999 else if value < -0.99 then -0.999 else value;
def fish = 0.5 * (log((1 + truncValue) / (1 - truncValue)) + fish[1]);

plot FTOneBarBack = fish[1];
plot FT = fish;
plot ZeroLine = 0;

FTOneBarBack.SetDefaultColor(color.cyan);
FT.SetDefaultColor(color.yellow);
ZeroLine.SetDefaultColor(color.white);

input paintbars = yes;

DefineglobalColor("Bullish", color.green);
DefineglobalColor("Bearish", color.red);

assignPriceColor(if !paintbars then color.current else if paintbars && FT >= FTOneBarBack then globalColor("Bullish") else if paintbars && FT < FTOneBarBack then globalColor("Bearish") else color.current);