True Strength Index with Bollinger Bands

December 23rd, 2014, 04:02 PM

I am looking for the TSI with its own Bollinger Bands.

It would be like the MACD with Bollinger Bands only using the TSI instead of the MACD.

Need this for the think or swim platform.

Any help I can get it will be greatly appreciated.

Thank you,

Don

December 24th, 2014, 01:41 PM

Gave it a shot:

Code

declare lower;

# True Strength Index

input longLength = 25;
input shortLength = 13;
input signalLength = 8;
input averageType = AverageType.EXPONENTIAL;

def diff = close - close[1];
plot TSI;
plot Signal;

TSI = (MovingAverage(averageType, MovingAverage(averageType, diff, longLength), shortLength))
    / (MovingAverage(averageType, MovingAverage(averageType, AbsValue(diff), longLength), shortLength)) * 100;
Signal = MovingAverage(averageType, TSI, signalLength);

plot ZeroLine = 0;

TSI.SetDefaultColor(GetColor(1));
Signal.SetDefaultColor(GetColor(8));
Signal.Hide();
ZeroLine.SetDefaultColor(GetColor(5));


# Bollinger Bands

input BbLength = 20;
input BbNum_Dev = 2.0;

plot BB_Upper = reference BollingerBands(price = TSI, length = BBlength, Num_Dev_Dn = -BBNum_Dev, Num_Dev_Up = BBNum_Dev).UpperBand;
plot BB_Lower = reference BollingerBands(price = TSI, length = BBlength, Num_Dev_Dn = -BBNum_Dev, Num_Dev_Up = BBNum_Dev).Lowerband;
plot BB_Midline = reference BollingerBands(price = TSI, length = BBlength, Num_Dev_Dn = -BBNum_Dev, Num_Dev_Up = BBNum_Dev).MidLine;

True Strength Index with Bollinger Bands

Discussion in ThinkOrSwim

True Strength Index with Bollinger Bands