NexusFi: Find Your Edge


Home Menu

 





Bugs T$ading Journal/#'s


Discussion in Trading Journals

Updated
      Top Posters
    1. looks_one bugsbunny with 849 posts (312 thanks)
    2. looks_two kbit with 273 posts (218 thanks)
    3. looks_3 samhtrader with 54 posts (39 thanks)
    4. looks_4 hector24 with 52 posts (46 thanks)
      Best Posters
    1. looks_one hector24 with 0.9 thanks per post
    2. looks_two kbit with 0.8 thanks per post
    3. looks_3 samhtrader with 0.7 thanks per post
    4. looks_4 bugsbunny with 0.4 thanks per post
    1. trending_up 186,138 views
    2. thumb_up 855 thanks given
    3. group 38 followers
    1. forum 1,464 posts
    2. attach_file 75 attachments




Closed Thread
 
Search this Thread

Bugs T$ading Journal/#'s

  #1391 (permalink)
 
TheWizard's Avatar
 TheWizard 
Houston, TX
Market Wizard
 
Experience: Intermediate
Platform: NinjaTrader
Broker: Optimus Futures, AMP, CQG
Trading: 6E
Posts: 1,731 since Jun 2009
Thanks Given: 517
Thanks Received: 4,224


bugsbunny View Post
another simple chart with just trend added to it..

Bugs,

Hope you're feeling better soon. Pain is a nasty mistress.

What is the Black/White trend indicator in your chart - post # 1386.

Thanks!

After all, it's what you learn AFTER you know it all, that counts!
Thanked by:

Can you help answer these questions
from other members on NexusFi?
NexusFi Journal Challenge - April 2024
Feedback and Announcements
New Micros: Ultra 10-Year & Ultra T-Bond -- Live Now
Treasury Notes and Bonds
Build trailing stop for micro index(s)
Psychology and Money Management
Futures True Range Report
The Elite Circle
Are there any eval firms that allow you to sink to your …
Traders Hideout
 
Best Threads (Most Thanked)
in the last 7 days on NexusFi
Get funded firms 2023/2024 - Any recommendations or word …
59 thanks
Funded Trader platforms
36 thanks
NexusFi site changelog and issues/problem reporting
25 thanks
The Program
20 thanks
GFIs1 1 DAX trade per day journal
19 thanks
  #1392 (permalink)
 bugsbunny 
toronto,ontaio
 
Posts: 973 since May 2010


hector24 View Post
Bugs I hope you get better.

Hector


@hector24 I wish i traded today... I was 100% accurate with what i gave away....but wasnt there to follow up with others... Im even more down today.... for other reasons.....

I hope that i feel better soon.... & can lead the pack again as i used too..... I dont wanna pump & dump...
God be with me & others....

God Bless

Bugs

  #1393 (permalink)
 bugsbunny 
toronto,ontaio
 
Posts: 973 since May 2010



TheWizard View Post
Bugs,

Hope you're feeling better soon. Pain is a nasty mistress.

What is the Black/White trend indicator in your chart - post # 1386.

Thanks!

Thanks for your concern @TheWizard The trend indi is a proprietary indicator Im trying to resemble it with one of the indicators here.. cause its just an ma I believe.. If youve read my post in the begining ive explained why I cant share the originals... & i hope you respect that too.....

As soon as i find something similar i will share....


Bugs

  #1394 (permalink)
 
Tiberius's Avatar
 Tiberius 
Coos County New Hampshire
 
Experience: Intermediate
Platform: NinjaTrader
Broker: IB
Trading: ES
Posts: 1,552 since Feb 2010
Thanks Given: 2,984
Thanks Received: 3,406


bugsbunny View Post
Thanks for your concern @ TheWizard The trend indi is a proprietary indicator Im trying to resemble it with one of the indicators here.. cause its just an ma I believe.. If youve read my post in the begining ive explained why I cant share the originals... & i hope you respect that too.....

As soon as i find something similar i will share....


Bugs

as a quick look, IMHO, it may resemble..................anaDoubleStochastics. ????????????

hope you feel better soon, bb

Visit my NexusFi Trade Journal
Thanked by:
  #1395 (permalink)
 bugsbunny 
toronto,ontaio
 
Posts: 973 since May 2010


Tiberius View Post
as a quick look, IMHO, it may resemble..................anaDoubleStochastics. ????????????

hope you feel better soon, bb

You are rite @Tiberius but i have to play with its settings to come close to what it produces... good call though I was thinking of that one too...

bugs

  #1396 (permalink)
 bugsbunny 
toronto,ontaio
 
Posts: 973 since May 2010

has anyone heard of an adaptive MACD??????

I have this material for it..... some code from TOS

The Adaptive MACD with OBOS and Heiken Ashi Indicators


The MACD is often described as a momentum indicator, an easily understood misinterpretation. The histogram actually indicates acceleration which is a change to momentum, but when momentum is constant the MACD histogram is featureless while the Two Lines indicate the direction and velocity of the current trend. (Momentum should include volume).

The Adaptive MACD uses the Adaptive Moving Average for the slow average and an ordinary EMA for the Fast and Smoothing Averages; the normal MACD uses EMA for all 3 averages. This study is indicated in percent of the slow average price, so the value is the price difference between the averages. Because the AMA accelerates in strong trends this Histogram amplifies trend changes more than simple acceleration in the direction of the current trend.

The plots include a variation of the OBOS (Over Bought/Over Sold) indicator. This shows the price range (lows and highs) relative to the slow average of the MACD. Normally we have this one hidden from view, but you may find it useful for entry/exit rules on channeling cyclic stocks. I generally scale off the slow average, a bounce off the fast average is a bounce off the MACD Signal line, a bounce off the slow average is a bounce off the Zero line.

The main information is on the 2-line MACD with Histogram. The MACD is the difference between 2 Exponential Moving Averages (EMAs), that difference is smoothed with another EMA. The Signal line is the difference, the Smoothed line is the difference passed through an EMA. The histogram is the difference between those 2 lines.

I have added Heiken-Ashi trend indicators. They show the first bull and first bear candles and highlight doji candles which suggest possible trend changes... I show these next to the Signal line.

There are several plots within this script, each of which provides useful information:
  • OBOS - Plot of the Close relative to the selected (slow or fast) average of the MACD - we usually have these turned off, but in a channeling cyclic it may be useful.
    • Cloud showing the Highs and Lows around the OBOS line, scaled to the MACD.
  • MSig - The Signal Line of the MACD, unfiltered difference between the AMA and EMA studies. This is colored in relation of the price and the fast (EMA) average.
  • MAvg - the Smoothed Line is the Signal smoothed by another EMA. This is colored according to the state of the PSAR study.
  • MACD - The histogram with 4 colors to indicate bar-to-bar price action.
  • MZero - The zero line with 3 colors to indicate the price action relative to the slow (AMA) average.
  • Heiken-Ashi Indicators
    • First Bull Candle
    • First Bear Candle
    • Doji
There are 4 inputs to this study you can set in addition to changing the default colors and line styles:
  • fastLength - Number of bars in the Fast AMA Average
  • slowLength - Number of bars in the Slow AMA Average
  • effRatioLength - Time for AMA Fast/Slow transition
  • mFastExp - Number of bars in the EMA (Fast Line)
  • mSmooth - Smoothing for the Signal Line
  • OBOSBase - Slow or Fast Average for scaling of the OBOS Signals
  • ATRLength - Length for an Exponential Average of the True Range
  • ATRScale - Multiplier for the ATR for trend color indications on the study lines
  • SARAccFactor - Acceleration Factor (Multiplier) for the Parabolic Stop and Reverse (PSAR) used to color the smoothed line
  • SARAccLimit - Acceleration Limit for the PSAR used to color the smoothed line
  • CrossSoundType - Sound selection for the Alert signal on acceleration changes intra-candle
  • CloseSoundType - Sound selection for the Alert signal on acceleration changes on closing of candles
  • SARSoundType - Sound sleection for the Alert signal on SAR state changes
Applications

This MACD indicates potential trend changes more strongly than simple acceleration within the trend. This is because the AMA leans toward a fast average in trends and a slow average in consolidation.

When the Signal line is rising (or falling) this may signal the start of a new trend. When the line is flat indicates an established trend. Its motion and separation from the Smoothed line indicate the strength of the trend change.This line is colored based on the price being above or below the Fast average (the EMA) by a multiple of an ATR.

When the Smoothed line is rising (or falling) it may act as support/resistance for the Signal line, indicating a new trend. When this line is flat it indicates an established trend. This line is colored based on the state of a Parabolic SAR study.

The histogram, being the difference between the Signal and Smoothed lines, indicates the acceleration of price within the current trend of the underlying; with the AMA emphasizing trend changes. This study is colored based on its own tick movement.

The Zero line is colored based on the price being above or below the Slow average (the AMA) by a multiple of an ATR.

You can also use different averages for the MACD studies to produce results for different time scales. We use the defaults for most of our applications of this study. We use Day, 2 Hour, and 15 Minute scales most often, depending on the volatility of the market at any given time. You can tune your AMA by just adding an AMA study to the upper chart and tweaking the parameters to get something you like for what you are trading.

I have added Overbought/Oversold (OBOS) indicators to this study. In channels they can help identify support and resistance while in trends they can help identify points to re-enter or add to a position. For example 1 May 2011 was a sharp, strong reversal day where Day and 2-Hour candles indicate no low-risk entry points, the 15-minute chart indicates several bounces of the OBOS from the fast average, indicating relatively low-risk entries on that time scale; if the trend continues then you can move your exit conditions to a longer time scale - if your rules permit exit condition adjustments. A cloud on the OBOS indicator shows the high and low scaled to the MACD.

I have added the Heiken-Ashi indicators on this study because while I find the candles themselves relatively useless, they do highlight trends nicely if a couple candles late for great entry...

Alerts are included to indicate a SAR state change as well as acceleration changes on the OBOS study.

MACD_Adaptive

# MACD_Adaptive
# (C) StarQuest Systems 2011
#
# MACD using Adaptive Moving Average for Slow Average
#
# Plots 2 Lines Plus Histogram
# Colors on Histogram for Above/Below 0 and Up/Down Tick
# Colors on Zero for Price Above/Below Fast Average
# Plots Overbought/Oversold(OBOS) for close/high/low
# Plots Heiken-Ashi indicators for Trend Indicators

input fastLength = 3;
input slowLength = 20;
input effRatioLength = 10;
input MFastExp = 5;
input MSmooth = 20;
input OBOSBase = { off, default slow, fast };
input ATRLength = 15;
input ATRScale = 0.10;
input SARAccFactor = 0.02;
input SARAccLimit = 0.2;
input CrossSoundType = {"NoSound", "Bell", "Chimes", "Ding", default "Ring"};
input CloseSoundType = {"NoSound", "Bell", "Chimes", default "Ding", "Ring"};
input SARSoundType = {"NoSound", "Bell", "Chimes", "Ding", default "Ring"};

declare lower;

#hint:<b>StarQuest Adaptive MACD</b>\nPlots a MACD lines plus Histogram using an Exp Average for the fast average and an Adaptive Moving Average for the slow average, smoothed by and Exp Average. This Study also includes Overbought/Oversold Indicator (hi/lo/close scaled to the selected average), as well as Heiken-Ashi candle markers showing an arrow at the first bullish or bearish candle and a dot on doji candles. The Signal Line is colored based on the price being above or below the Fast average by an ATR multiple. The Smoothed line is colored based on a Parabolic SAR state. The Histogram is colored based on its own tick change. The Zero line is colored based on the price being above or below the Slow average by an ATR multiple.
#hint fastLength: The AMA Fast Average Length. (Default is <b>2</b>)
#hint slowLength: The AMA Slow Average Length. (Default is <b>30</b>)
#hint effRatioLength: The AMA Effective Ratio Length. (Default is <b>10</b>)
#hint MFastExp: The Fast EMA Length. (Default is <b>5</b>)
#hint MSmooth: The Histogram Smoothing Length. (Default is <b>20</b>)
#hint OBOSBase: Select the Slow or Fast Average for the OBOS Signal Lines. (Default is <b>Slow</b>)
#hint ATRLength: ATR Length for Momentum Change Alerts. (Default is <b>15</b>)
#hint ATRScale: ATR Scaling Factor for Momentum Change Alerts. (Default is <b>0.10</b>)
#hint SARAccFactor: SAR acceleration factor (Default is <b>0.02</b>)
#hint SARAccLimit: SAR acceleration limit (Default is <b>0.2</b>)
#hint CrossSoundType: Sound for alert when Momentum reverses or accelerates. (Default is <b>Ring</b>)
#hint CloseSoundType: Select the Slow or Fast Average for the OBOS Signal Lines. (Default is <b>Ding</b>)
#hint SarSoundType: Sound for alert when SAR reverses. (Default is <b>Ring</b>)

DefineGlobalColor("OBOShl",CreateColor(255, 102, 0));

# Compute the PSAR value
rec state = {default init, long, short};
rec extreme;
rec SAR;
rec acc;

switch (state[1]) {
case init:
state = state.long;
acc = SARAccFactor;
extreme = high;
SAR = low;
case short:
if (SAR[1] < high)
then {
state = state.long;
acc = SARAccFactor;
extreme = high;
SAR = extreme[1];
} else {
state = state.short;
if (low < extreme[1])
then {
acc = min(acc[1] + SARAccFactor, SARAccLimit);
extreme = low;
} else {
acc = acc[1];
extreme = extreme[1];
}
SAR = max(max(high, high[1]), SAR[1] + acc * (extreme - SAR[1]));
}
case long:
if (SAR[1] > low)
then {
state = state.short;
acc = SARAccFactor;
extreme = low;
SAR = extreme[1];
} else {
state = state.long;
if (high > extreme[1])
then {
acc = min(acc[1] + SARAccFactor, SARAccLimit);
extreme = high;
} else {
acc = acc[1];
extreme = extreme[1];
}
SAR = min(min(low, low[1]), SAR[1] + acc * (extreme - SAR[1]));
}
}
alert(state != state[1], "SAR State Change", alert.bar, SARSoundType);

# Compute Adaptive Moving Average as the Slow Average...
def direction = AbsValue(close - close[effRatioLength]);
def volatility = sum(AbsValue(close - close[1]), effRatioLength);
#def volatility = fVolCommon + AbsValue(close - close[1]);
def ER = if volatility != 0 then direction / volatility else 0;
def FastSF = 2 / (fastLength + 1);
def SlowSF = 2 / (slowLength + 1);
def ScaledSF = ER * (FastSF - SlowSF) + SlowSF;
rec AMA = compoundValue(1, AMA[1] + Sqr(ScaledSF) * (close - AMA[1]), close);
def fFastAvg = ExpAverage(close, MFastExp);

def xATR = ExpAverage(TrueRange(high, close, low), ATRLength);
def xMargin = ATRScale * xATR;

def bUpTick = (close > (fFastAvg + xMargin));
def bDnTick = (close < (fFastAvg - xMargin));

def fRefAvg;
switch (OBOSBase)
{
case off:
fRefAvg = Double.NaN;
case slow:
fRefAvg = AMA;
case fast:
fRefAvg = fFastAvg;
}
# Over Bought / Over Sold Indicator
plot OBOS = 100 * (close - fRefAvg) / fRefAvg[1];
OBOS.SetDefaultColor(CreateColor(255, 102, 0));
OBOS.SetLineWeight (2);
def fOBOSH = 100 * (high - fRefAvg) / fRefAvg[1];
def fOBOSL = 100 * (low - fRefAvg) / fRefAvg[1];
AddCloud(fOBOSH, fOBOSL, GlobalColor("OBOShl"), GlobalColor("OBOShl"));

# MACD Signal
plot MSig = 100 * (fFastAvg - AMA) / AMA[1];
MSig.SetDefaultColor(CreateColor(0, 0, 153));
MSig.SetLineWeight (2);
MSig.DefineColor("UpTick", Color.GREEN);
MSig.DefineColor("Neutral", Color.BLUE);
MSig.DefineColor("DnTick", Color.RED);
MSig.DefineColor("NoData", Color.BLACK);
MSig.AssignValueColor(if IsNaN(MSig) then MSig.color("NoData") else if bUpTick then MSig.color("UpTick") else if bDnTick then MSig.color("DnTick") else MSig.color("Neutral"));
# MACD Signal Smoothed
plot MAvg = ExpAverage(MSig, MSmooth);
MAvg.SetDefaultColor(CreateColor(0, 0, 153));
MAvg.SetLineWeight (3);
MAvg.DefineColor("SARUp", Color.GREEN);
MAvg.DefineColor("SARDn", Color.RED);
MAvg.DefineColor("NoData", Color.BLACK);
MAvg.SetLineWeight(3);
MAvg.AssignValueColor(if IsNaN(MSig) then MAvg.color("NoData") else if (state==state.long) then MAvg.color("SARUp") else MAvg.color("SARDn"));
AddCloud(MSig,MAvg,MAvg.color("SARUp"),MAvg.color("SARDn"));

# MACD Histogram
plot MACD = MSig - MAvg;
MACD.SetDefaultColor(CreateColor(0, 0, 153));
MACD.SetLineWeight (3);
MACD.SetPaintingStrategy(paintingStrategy.HISTOGRAM);
MACD.DefineColor("PosUp", CreateColor(51, 255, 51));
MACD.DefineColor("PosDn", CreateColor(0, 204, 0));
MACD.DefineColor("NegDn", CreateColor(255, 51, 51));
MACD.DefineColor("NegUp", CreateColor(204, 0, 0));
MACD.AssignValueColor(if MACD >= 0 then if MACD > MACD[1] then MACD.color("PosUp") else MACD.color("PosDn") else if MACD < MACD[1] then MACD.color("NegDn") else MACD.color("NegUp"));

def bUpSlow = (close > (AMA + xMargin));
def bDnSlow = (close < (AMA - xMargin));
plot MZero = 0;
MZero.SetStyle(curve.POINTS);
MZero.SetDefaultColor(Color.BLACK);
MZero.SetLineWeight (2);
MZero.DefineColor("UpTick", Color.GREEN);
MZero.DefineColor("Neutral", Color.BLUE);
MZero.DefineColor("DnTick", Color.RED);
MZero.DefineColor("NoData", Color.BLACK);
MZero.AssignValueColor(if IsNaN(MACD) then MZero.color("NoData") else if bUpSlow then MZero.color("UpTick") else if bDnSlow then MZero.color("DnTick") else MZero.color("Neutral"));

#Momentum Alerts
def fOBOSMove = OBOS - OBOS[1];
def fMomMargin = 100*xMargin/fRefAvg[1];
def bMomUp = (fOBOSMove > fMomMargin);
def bMomDn = (fOBOSMove < -fMomMargin);
def dirMom = if bMomUp then 1.0 else if bMomDn then -1.0 else 0.0;
plot MomUp = if bMomUp AND !bMomUp[1] then fOBOSL else Double.NaN;
MomUp.SetDefaultColor(CreateColor(0, 153, 0));
MomUp.SetLineWeight(1);
MomUp.SetPaintingStrategy(PaintingStrategy.ARROW_UP);
MomUp.SetStyle(Curve.POINTS);
plot MomDn = if bMomDn AND !bMomDn[1] then fOBOSH else Double.NaN;
MomDn.SetDefaultColor(CreateColor(153, 0, 0));
MomDn.SetLineWeight(1);
MomDn.SetPaintingStrategy(PaintingStrategy.ARROW_DOWN);
MomDn.SetStyle(Curve.POINTS);

alert(bMomUp[1] AND !bMomUp[2], "Acceleration Close Above", alert.bar, CloseSoundType);
alert(bMomDn[1] AND !bMomDn[2], "Acceleration Close Below", alert.bar, CloseSoundType);

alert(bMomUp AND !bMomUp[1], "Acceleration Move Up", alert.bar, CrossSoundType);
alert(bMomDn AND !bMomDn[1], "Acceleration Move Down", alert.bar, CrossSoundType);

# Heiken-Ashi Trend Indicators
def xHAClose = ((open + close + high + low) / 4);
rec xHAOpen = compoundValue(1, xHAOpen[1] + xHAClose[1], open + close) / 2;
def xHAHigh = Max(high, Max(xHAOpen, xHAClose));
def xHALow = Min(low, Min(xHAOpen, xHAClose));

def bHABull = ((xHAClose - xHAOpen) > (0.1 * xATR));
def bHABear = ((xHAOpen - xHAClose) > (0.1 * xATR));
def bHADoji = !(bHABull OR bHABear);

plot HABull = if bHABull AND !bHABull[1]
then fOBOSL else Double.NaN;
HABull.SetDefaultColor(CreateColor(255, 204, 51));
HABull.SetPaintingStrategy(PaintingStrategy.ARROW_UP);
HABull.SetStyle(Curve.POINTS);
HABull.SetLineWeight(3);
plot HABear = if bHABear AND !bHABear[1]
then fOBOSH else Double.NaN;
HABear.SetDefaultColor(CreateColor(255, 204, 51));
HABear.SetPaintingStrategy(PaintingStrategy.ARROW_DOWN);
HABear.SetStyle(Curve.POINTS);
HABear.SetLineWeight(3);
plot HADoji = if bHADoji
then MAvg else Double.NaN;
HADoji.SetDefaultColor(CreateColor(255, 204, 51));
HADoji.SetPaintingStrategy(PaintingStrategy.POINTS);
HADoji.SetStyle(Curve.POINTS);
HADoji.SetLineWeight(5);

  #1397 (permalink)
 
Tiberius's Avatar
 Tiberius 
Coos County New Hampshire
 
Experience: Intermediate
Platform: NinjaTrader
Broker: IB
Trading: ES
Posts: 1,552 since Feb 2010
Thanks Given: 2,984
Thanks Received: 3,406


bugsbunny View Post
You are rite @ Tiberius but i have to play with its settings to come close to what it produces... good call though I was thinking of that one too...

bugs

also the BlueLine

Attached Files
Elite Membership required to download: BLine.cs
Elite Membership required to download: BLine_MultiColor.cs
Visit my NexusFi Trade Journal
Thanked by:
  #1398 (permalink)
 bugsbunny 
toronto,ontaio
 
Posts: 973 since May 2010


Tiberius View Post
also the BlueLine


@Tiberius what is the blue line can you update me with it...

Thanks


Bugs

  #1399 (permalink)
 bugsbunny 
toronto,ontaio
 
Posts: 973 since May 2010


Tiberius View Post
also the BlueLine


something to look @ play with when I have some time

  #1400 (permalink)
 
TheWizard's Avatar
 TheWizard 
Houston, TX
Market Wizard
 
Experience: Intermediate
Platform: NinjaTrader
Broker: Optimus Futures, AMP, CQG
Trading: 6E
Posts: 1,731 since Jun 2009
Thanks Given: 517
Thanks Received: 4,224



Tiberius View Post
as a quick look, IMHO, it may resemble..................anaDoubleStochastics. ????????????

hope you feel better soon, bb

TIberius,

Good call ! anaDoubleStochastics (200, 75) seems to be a fairly good fit. May have to play around with the settings some more.

After all, it's what you learn AFTER you know it all, that counts!
Thanked by:

Closed Thread



Last Updated on September 23, 2011


© 2024 NexusFi™, s.a., All Rights Reserved.
Av Ricardo J. Alfaro, Century Tower, Panama City, Panama, Ph: +507 833-9432 (Panama and Intl), +1 888-312-3001 (USA and Canada)
All information is for educational use only and is not investment advice. There is a substantial risk of loss in trading commodity futures, stocks, options and foreign exchange products. Past performance is not indicative of future results.
About Us - Contact Us - Site Rules, Acceptable Use, and Terms and Conditions - Privacy Policy - Downloads - Top
no new posts