#region - Documentation -
{
---------------------------------------------------------------------------------------------------
IDENTIFICATION
==============
Name:			RS_TheSTRAT
Type:			Indicator
TS Version:		9.5 Build 26 or later
  
---------------------------------------------------------------------------------------------------
CRITICAL INFO
=============
*    Be sure that "Update value intra-bar (tick-by-tick) IS NOT CHECKED

DOCUMENTATION
=============
This indicator will label the bars with a number indicating one of the following conditions:

* 	If the current bars High or Low is equal OR does not exceed the previous bar's High OR Low, it will be a "1" (Inside Bar)
*	If a candle exceeds the High OR the Low of the previous bar BUT not both, it will be a "2" (Note, equal to prev H/L does not count as exceeds)
*	If a candle exceeds both the High and the Low of the previous bar it will be a "3"  (Outside Bar)

*   Added (4/24/2020 by JPoole) - If bar scores a "2" as stated above, then also need to determine if it is a "2Up" or "2Dn"
    2Up = Any bar that scores a 2 AND Makes a Higher High than the prev bar - Change color of text label to "Green"
    2Dn = Any bar that scores a 2 AND makes a Lower Low than the prev bar - Change color of text label to "Red"

*   To Be Added - RadarSceen Plots - Conditions & Alerts for each of the following;
    Single Bar Condition:
    Current Condition (i.e. 1, 2Up or 2Dn, 3)
    Multi-Bar Alerts:
    2Up/1/2Up = "Bullish Continuation Condition"
    2Dn/1/2Dn = "Bearish Continuation Condition"
    2Up/2Dn = "2 Bar Bearish Reversal Condition"
    2Dn/2Up = "2 Bar Bullish Reversal Condition"
    1/2Up/2Dn = "3 Bar Bearish Reversal Condition"
    1/2Dn/2Up = "3 Bar Bullish Reversal Condition"
    
*   To be Added - Is there a way to remove the "Exceeded 5000 text objects" warning, it may be annoying to some users
    
---------------------------------------------------------------------------------------------------
}
#endregion

#region - History -
{
---------------------------------------------------------------------------------------------------
HISTORY
=======
Date		Version		Task
---------	--------	-------------------------------------------------------------------
03/26/20	01.00.00	* Created 
							
---------------------------------------------------------------------------------------------------
TO DO LIST
==========
Date		Version		Task
---------	--------	-------------------------------------------------------------------

---------------------------------------------------------------------------------------------------
}
#endregion

#region - Usings -
using elsystem;
using elsystem.collections;
using elsystem.drawing;
using elsystem.drawingobjects;
#endregion

#region - Inputs_Study -
inputs:
	int iMaxBars(100),
	string iLabelColor("Magenta"),
	float iFontSize(8);
#endregion

#region - Variables_Study -
variables:
	Vector TxtLbls(null),
	TextLabel TxtLbl(null),
	intrabarpersist int LastBar(0),
	string STRAT_State("");
#endregion

method TextLabel AddLabel()
variables:
	TextLabel TX;
begin
	TX = TextLabel.Create();
	TX.Color = Color.FromName(iLabelColor);
	TX.Font = Font.Create(TX.Font.Name, iFontSize, FontStyle.Regular);
	TX.HStyle = HorizontalStyle.Center;
	TX.VStyle = VerticalStyle.Center;
	TX.Lock = true;
	TX.Name = string.format("{0}", CurrentBar);
	TX.Persist = true;
	TX.PointValue = BNPoint.Create(CurrentBar + MaxBarsBack - 1, High + .10);
	TX.TextString = STRAT_State;

	DrawingObjects.Add(TX);
	return TX;
end;

once
begin
	TxtLbls = vector.create();
end;

//	Determine Value to be displayed

STRAT_State = "";

if High <= High[1]
	and Low >= Low[1] then
begin
	STRAT_State = "1";
	Plot1(STRAT_State, "1", White, Default, 2);
	Print("1");
	Alert("1");
end

else if (High > High[1] and Low >= Low[1] )Then
begin
	STRAT_State = "2U";
	Plot2(STRAT_State, "2U", White, Default, 2);
	Print("2U");
	Alert("2U");
end

else if (High <= High[1] and Low < Low[1] ) then
begin
	STRAT_State = "2D";
	Plot3(STRAT_State, "2D", White, Default, 2);
	Print("2D");
	Alert("2D");
end

else if High > High[1] and Low < Low[1] then
begin
	STRAT_State = "3";
	Plot4(STRAT_State, "3", White, Default, 2);
	Print("3");
	Alert("3");
end;

if STRAT_State.Length > 0 then
begin
	AddLabel();
end;


if iMaxBars > 0 then
begin
	if CurrentBar > LastBar then
	begin
		LastBar = CurrentBar;
		TxtLbl = AddLabel();
		TxtLbls.Push_Back(TxtLbl);
		
		while TxtLbls.count > iMaxBars
		begin
			DrawingObjects.Delete(TxtLbls[0] astype TextLabel);
			TxtLbls.erase(0);
		end;
	end
	
	//	Position Label
	else if TxtLbl <> null then
	begin
		TxtLbl.PointValue = BNPoint.Create(CurrentBar + MaxBarsBack - 1, (Open + Close) / 2);
		end;
	
end;