Daily ATR on Intraday Data

November 20th, 2013, 09:25 PM

I use the ATR on the daily bars quote a bit, but am working with a intraday strategy and would like to get the ATR that is the same as the day chart with out actually have to plot the daily bars because this slows MC down a lot. can anyone suggest any pointers in the best way to try to calculate the daily ATR on intraday bars with out doing ATR = Close of data2;

November 20th, 2013, 10:05 PM

actually i found the function : RS_TrueExtremes which says suppose to do the same thing

RS_TrueExtremes (Function)

but when i load up the example and compare a 9 day ATR on intraday data vs a 9 day ATR on normal data they are very different...

November 30th, 2013, 11:54 AM

you can read this:
Tutorial 34 - Using ADE (All Data Everywhere) to transfer data between charts
also tutorial n.32.

i think should be helpful for you.
bye

November 30th, 2013, 05:19 PM

I think Highd(0) - Lowd(0) will give the range for the current day, intra-day data.. (prev close would be Closed(1);
If you want ave true range you would have to allow for the gaps from the prev close, shouldn't be too hard to do..

December 9th, 2013, 06:57 AM

I posted this code for daily atr for intraday charts somewhere on the Multicharts forum some years ago:

Code

Input: 
Modus 	  ( 1 ),
//Modus = 1 : Calculate the ATR including the current date, the ATR drops on the start of the trading
//day. Same calculation as on a daily chart using the standard
//Average True Range function with "Update on every tick" checked
//Modus = 2 : Calculate the ATR over the last ATRLength days excluding today. 
//Same calculation as on a daily chart using the standard
//Average True Range function with "Update on every tick" unchecked
ATRLength( 30 ); 

Variables: 
x		(0), 
AvDailyAtr 	(0),  
Initialized	(0); 

Array : MyATR [50] (0); //Limit to 50 as OHLCPeriodsAgo used by TrueRangeD /HighD... is
//limited to arr0[ 4, 50 ]( -1 ) 

once begin
	if ATRLength >49 then raiseruntimeerror (" ATRLength needs to be <50 !!!!");
     end;	
If date <> date[1] then 
begin 
	Initialized = Initialized + 1; 
		If Bartype < 2 and initialized > ATRLength then 
			begin 
				for x = 1 to ATRLength-1 
					begin 
						MyATR [x] = TrueRangeD ( x);
					end; 
			end;
end;

if Modus = (1) then MyATR [0]  = TrueRangeD ( 0 );
if Modus = (2) then MyATR [0]  = TrueRangeD ( ATRLength );

AvDailyAtr = array_sum ( MyATR ,0,ATRLength-1 )/ATRLength;

If initialized > ATRLength then 
Plot1(AvDailyAtr ,"Daily ATR");

Daily ATR on Intraday Data

Discussion in MultiCharts

Daily ATR on Intraday Data