VIDEO TUTORIAL: How to create an advanced MultiCharts EasyLanguage Strategy

Big Mike · June 4th, 2011, 02:29 AM

Last year I did a video tutorial on creating an advanced NinjaTrader strategy, and you guys liked it. So I thought that since I don't use NT any more it would be a good idea to do the same strategy as an example in EasyLanguage with MultiCharts.

First, here is a link to the NinjaTrader Video Tutorial:
https://futures.io/ninjatrader/2512-video-tutorial-how-create-advanced-ninjatrader-strategy.html

OK, so in this video I show you how to create a strategy with optimizable parameters such as SMA length, EMA length, HMA length, three different targets, a stop, and the option to move target 2 to breakeven after target 1 is hit, as well as an option to move target 3 to breakeven after target 2 is hit.

Remember, this strategy is just an example! It took only a few minutes to write, and even though it shows to be profitable - it isn't (it won't be). Simple strategies are usually best to avoid curve fitting, but this one is too simple to actually work fully automated. A good strategy may take dozens of hours to create.

This example was created just so you could get your feet wet and learn some of the basics of strategy creation in MultiCharts or EasyLanguage.

Mike

Big Mike · June 4th, 2011, 02:29 AM

Here is the code for jtHMA function if you need it:

Code

                            


{jtHMA - Hull Moving Average Function}

{Author: Atavachron}

{May 2005}



Inputs: price(NumericSeries), length(NumericSimple);

Vars: halvedLength(0), sqrRootLength(0);



{

Original equation is:

---------------------

waverage(2*waverage(close,period/2)-waverage(close ,period), SquareRoot(Period)

Implementation below is more efficient with lengthy Weighted Moving Averages.

In addition, the length needs to be converted to an integer value after it is halved and

its square root is obtained in order for this to work with Weighted Moving Averaging

}



if ((ceiling(length / 2) - (length / 2)) <= 0.5) then

halvedLength = ceiling(length / 2)

else

halvedLength = floor(length / 2);



if ((ceiling(SquareRoot(length)) - SquareRoot(length)) <= 0.5) then

sqrRootLength = ceiling(SquareRoot(length))

else

sqrRootLength = floor(SquareRoot(length));



Value1 = 2 * WAverage(price, halvedLength);

Value2 = WAverage(price, length);

Value3 = WAverage((Value1 - Value2), sqrRootLength);



jtHMA = Value3;

Mike

Big Mike · June 4th, 2011, 02:30 AM

Here is the code for the strategy created in our video example. I've also attached a MultiCharts pla to make it easy for importing, and that pla also contains the jtHMA function (since HMA is not built-in to MultiCharts).

Code

                            


{

Big Mike Trading https://futures.io

June 2011

}





inputs:

    smalength ( 200 ),

    emalength ( 100 ),

    hmalength ( 34 ),

    target1 ( 12 ),

    target2 ( 12 ),

    target3 ( 20 ),

    stopsize ( 12 ),

    BE2 ( 0 ), // 0=false, 1=true

    BE3 ( 0 ); // 0=false, 1=true

    

vars:

    TickSize    ( MinMove / PriceScale ),

    smav        ( 0 ),

    emav        ( 0 ),

    hmav        ( 0 ),

    t1        ( Target1 * TickSize ),

    t2        ( (Target1 + Target2) * TickSize ),

    t3        ( (Target1 + Target2 + Target3) * TickSize ),

    st1        ( 0 ),

    st2        ( 0 ),

    st3        ( 0 );

    

smav = Average(Close, smalength);

emav = XAverage(Close, emalength);

hmav = jtHMA(Close, hmalength);





// open new positions



if MarketPosition = 0 then begin



    if smav > smav[1] and emav > emav[1] and hmav > hmav[1] then begin

    

        Buy ("Enter long") 3 Contracts Next Bar At Market;

    

    end; 



    if smav < smav[1] and emav < emav[1] and hmav < hmav[1] then begin

    

        SellShort ("Enter short") 3 Contracts Next Bar At Market;

    

    end; 

end;



// manage open orders



if MarketPosition = 1 then begin



    st1 = EntryPrice - (stopsize * TickSize);

    st2 = iff(BE2 = 1, EntryPrice, EntryPrice - (stopsize * TickSize));

    st3 = iff(BE3 = 1, EntryPrice, EntryPrice - (stopsize * TickSize));

    

    if CurrentContracts = 1 then begin

        Sell ("Exit l3-c1 Target") 1 Contracts Next Bar At (EntryPrice + t3) Limit;

        Sell ("Exit l3-c1 Stop") 1 Contracts Next Bar At st3 Stop;

    end;



    if CurrentContracts = 2 then begin

        Sell ("Exit l2-c2 Target") 1 Contracts Next Bar At (EntryPrice + t2) Limit;

        Sell ("Exit l2-c2 Stop") 1 Contracts Next Bar At st2 Stop;

        Sell ("Exit l3-c2 Target") 1 Contracts Next Bar At (EntryPrice + t3) Limit;

        Sell ("Exit l3-c2 Stop") 1 Contracts Next Bar At st3 Stop;

    end;

    

    if CurrentContracts = 3 then begin

        Sell ("Exit l1-c3 Target") 1 Contracts Next Bar At (EntryPrice + t1) Limit;

        Sell ("Exit l1-c3 Stop") 1 Contracts Next Bar At st1 Stop;

        Sell ("Exit l2-c3 Target") 1 Contracts Next Bar At (EntryPrice + t2) Limit;

        Sell ("Exit l2-c3 Stop") 1 Contracts Next Bar At st2 Stop;

        Sell ("Exit l3-c3 Target") 1 Contracts Next Bar At (EntryPrice + t3) Limit;

        Sell ("Exit l3-c3 Stop") 1 Contracts Next Bar At st3 Stop;

    end;

end;



if MarketPosition = -1 then begin



    st1 = EntryPrice + (stopsize * TickSize);

    st2 = iff(BE2 = 1, EntryPrice, EntryPrice + (stopsize * TickSize));

    st3 = iff(BE3 = 1, EntryPrice, EntryPrice + (stopsize * TickSize));

    

    if CurrentContracts = 1 then begin

        BuyToCover ("Exit s3-c1 Target") 1 Contracts Next Bar At (EntryPrice - t3) Limit;

        BuyToCover ("Exit s3-c1 Stop") 1 Contracts Next Bar At st3 Stop;

    end;



    if CurrentContracts = 2 then begin

        BuyToCover ("Exit s2-c2 Target") 1 Contracts Next Bar At (EntryPrice - t2) Limit;

        BuyToCover ("Exit s2-c2 Stop") 1 Contracts Next Bar At st2 Stop;

        BuyToCover ("Exit s3-c2 Target") 1 Contracts Next Bar At (EntryPrice - t3) Limit;

        BuyToCover ("Exit s3-c2 Stop") 1 Contracts Next Bar At st3 Stop;

    end;

    

    if CurrentContracts = 3 then begin

        BuyToCover ("Exit s1-c3 Target") 1 Contracts Next Bar At (EntryPrice - t1) Limit;

        BuyToCover ("Exit s1-c3 Stop") 1 Contracts Next Bar At st1 Stop;

        BuyToCover ("Exit s2-c3 Target") 1 Contracts Next Bar At (EntryPrice - t2) Limit;

        BuyToCover ("Exit s2-c3 Stop") 1 Contracts Next Bar At st2 Stop;

        BuyToCover ("Exit s3-c3 Target") 1 Contracts Next Bar At (EntryPrice - t3) Limit;

        BuyToCover ("Exit s3-c3 Stop") 1 Contracts Next Bar At st3 Stop;

    end;

    

end;

Mike

Big Mike · June 4th, 2011, 05:22 PM

Here is a follow-up. This is a 1-year backtest on the EUR/USD, 6 range chart, with $2 commission per side and $12.50 slippage per contract.

Results came back with 28k net profit on 2,159 trades, 40% win rate, w/l ratio of 1.56. However, when you look at the equity curve and other performance metrics, you'll see this strategy needs work. As expected. This video was just an example, you could use it as a starting point.

Mike

Big Mike · June 5th, 2011, 01:40 AM

Feel free to make a request for future video tutorials in this thread.

Mike

Family Trader · June 5th, 2011, 11:12 AM

Thank you for the presentation....very useful to a 'dumb techy' like me...worth a laugh when you apologized for having to type 'slow'...in comparison to the Ninja video where I had to hit the "pause" button a million times to follow what you were doing.

Hope your hand/wrist are healing well..

Trader

steelchueh · November 27th, 2011, 04:59 AM

Big Mike

Here is a follow-up. This is a 1-year backtest on the EUR/USD, 6 range chart, with $2 commission per side and $12.50 slippage per contract.

Results came back with 28k net profit on 2,159 trades, 40% win rate, w/l ratio of 1.56. However, when you look at the equity curve and other performance metrics, you'll see this strategy needs work. As expected. This video was just an example, you could use it as a starting point.

Mike

Very good to show me for the multiple contracts control in the MC..
Well, the MDD seems quite huge... for such strategy...
Thanks for your sharing, anyway,, I learned a lot!!
Wish for sharing more MC coding examples...

-Steel

erchis · May 8th, 2012, 03:08 AM

Hi Big Mike,
could you help me please with writing this simple strategy in EasyLanguage?

Strategy:

Indicators - EMA(x), SMA(y), MACD(m,n,o), CCI(p); where x<y

Our pozition is everytime e.g. 5 % of 100000$ - initial capital.

Bull's position:

Signal for entry- EMA(x) crosses up SMA(y), where x<y, and MACD>=0 ∧ CCI>=0

Moment of entry - closing price of the candle, in which crossover hapend

STOPLOSS - minimum of the candle, which is the lowest in recent x days, where x is EMA's period, (I think it is called SWING LOW) and it moves with time

PROFIT TARGET - is in the same distance like STOPLOSSE every time and when we achieve it, we close half amount of our position

Signal for exit- EMA(x) crosses down SMA(y), where x<y, in this moment we sell the second half of position or whole position in that case we didn't achieve PROFIT TARGET yet.

Bear's position
the rules are same but vice versa

That's it and I have also one suggestion for next video tutorial - how backtest portfolio in MultiCHarts

Thank you for any help
and I'm sorry for my bad English

erchis · May 8th, 2012, 01:02 PM

Hi,
I wrote some code according to the video and my trading rules above and tried it
on day chart of google, but it doesn't make any trades...is the algorithm correct?

Thanks very much

CODE:
---------------------------------------------------------------------------------------------------------------
inputs:

smalength ( 26 ),

emalength ( 8 ),

macdfastlength ( 5 ),

macdslowlength ( 10 ),

ccilength (14);

vars:

TickSize ( MinMove / PriceScale ),

smav ( 0 ),

emav ( 0 ),

macdv ( 0 ),

cciv ( 0 ),

money ( 70000 ),

stocks ( Close/money ),

tar ( 0 ),

st ( Close ),

timer ( 0 );

smav = Average(Close, smalength);

emav = XAverage(Close, emalength);

macdv = MACD(Close, macdfastlength , macdslowlength);

cciv = CCI(ccilength);

// open new positions

if MarketPosition = 0 then begin

if emav crosses over smav then begin
alert("prekrizeni nahoru");
if macdv >= 0 and cciv >= 0 then begin

Buy ("Enter long") stocks Contracts Next Bar At Market;

end;

end;

if emav crosses under smav then begin

if macdv < 0 and cciv < 0 then begin

SellShort ("Enter short") stocks Contracts Next Bar At Market;

end;

end;
end;

// manage open orders

if MarketPosition = 1 then begin // 1 - means long position opened

for timer = 0 to emalength - 1 begin
if st > Close[timer] then begin
st = Close[timer]; // stoploss on the swing low
end;
end ;
tar = Close + (Close - st);

Sell ("Exit long Target") stocks/2 Contracts Next Bar At tar Limit;

Sell ("Exit long Stop") currentcontracts Contracts Next Bar At st Stop;

end;

if MarketPosition = -1 then begin // -1 - means short position opened

for timer = 0 to emalength - 1 begin
if st < Close[timer] then begin
st = Close[timer]; // stoploss on the swing high
end;
end ;
tar = Close - (st - Close);

BuyToCover ("Exit short Target") stocks/2 Contracts Next Bar At tar Limit;

BuyToCover ("Exit short Stop") currentcontracts Contracts Next Bar At st Stop;

end;

guppy · May 21st, 2012, 11:21 PM

Hi Mike,

In your example, what if your profit or stop loss gets hit on the entry bar. How can you make it so that it will exit on the entry bar and not on the next bar?

Big Mike

Here is a follow-up. This is a 1-year backtest on the EUR/USD, 6 range chart, with $2 commission per side and $12.50 slippage per contract.

Results came back with 28k net profit on 2,159 trades, 40% win rate, w/l ratio of 1.56. However, when you look at the equity curve and other performance metrics, you'll see this strategy needs work. As expected. This video was just an example, you could use it as a starting point.

Mike

VIDEO TUTORIAL: How to create an advanced MultiCharts EasyLanguage Strategy

Wyckoff Hunting for Great Risk/Reward Ratio w/Gary Fullett

Digging into the Details of iSystems w/Stage 5 & iSystems

> Futures Trading, News, Charts and Platforms > Platforms and Indicators > MultiCharts

VIDEO TUTORIAL: How to create an advanced MultiCharts EasyLanguage Strategy

VIDEO TUTORIAL: How to create an advanced MultiCharts EasyLanguage Strategy

Wyckoff Hunting for Great Risk/Reward Ratio w/Gary Fullett

Digging into the Details of iSystems w/Stage 5 & iSystems