ZigZag expanded in time (code)

December 23rd, 2010, 03:25 PM

Hello everybody,

just thought the following code could be of interest for someone. It is a representation of zigzag, not in form of the well-known lines, but exactly the value of this indicator on each bar. Therefore you can follow its move during the forming of the most recent span, not only after a reversal occurs. The indicator uses two data streams: data1 is used for plotting and data2 � for determining the swing criterion. By default if is equal to 1 ATR of data2. The other lines on the chart are 2 standard errors from the uppermost or lowermost line (depending on the direction) and target levels for upwards and downwards movements. I hope the parameters are self-explanatory, but if you're in trouble please feel free to ask.

The indicator uses a function named __zigzagtrue_stddev__, please make sure the name is exactly that.

Code

input: period(numericSimple), factor_atr(numericSimple), factor_stddev(numericSimple), dir(numericRef), atr(numericRef), sd(numericRef);

var: xhigh(high), xlow(low);

xhigh = maxlist(high, xhigh);
xlow = minlist(low, xlow);

atr = avgtruerange(period) of data2 * factor_atr;
sd = stderror(close, period) of data2 * factor_stddev;

if low <= xhigh - atr and dir = 1 then begin
	dir = -1;
	xlow = low;
end;

if high >= xlow + atr and dir = -1 then begin
	dir = 1;
	xhigh = high;
end;

if dir = -1 then begin
	value1 = xlow;
end;
if dir = 1 then begin
	value1 = xhigh;
end;

__zigzagtrue_stddev__ = value1;

Now the indicator itself:

Code

input: period(20), factor_atr(2), factor_stddev(2), retracement(0.5);

var: xhigh(high), xlow(low), atr(0), dir(1), sd(0);

value1 = __zigzagtrue_stddev__(period, factor_atr, factor_stddev, dir, atr, sd);

if dir = -1 then begin
	setPlotColor(1, red);
	if dir[1] = 1 then value2 = value1 - atr;
	value3 = value1 + atr * retracement;
	value4 = value1 + sd;
	setPlotColor(2, red);
	setPlotColor(3, red);
	setPlotColor(4, white);
end;
if dir = 1 then begin
	setPlotColor(1, yellow);
	if dir[1] = -1 then value2 = value1 + atr;
	value3 = value1 - atr * retracement;
	value4 = value1 - sd;
	setPlotColor(2, yellow);
	setPlotColor(3, yellow);
	setPlotColor(4, white);
end;

plot1(value1);
plot2(value2);
plot3(value3);
plot4(value4);

If this stuff is apt for anyone please share your experience, would love also to hear about how this behaves on other instruments, in particular on index futures.

Hope I haven't dubbed someone else's work here on the forum.

December 28th, 2010, 11:25 AM

Thanks for sharing. Have you looked at SuperTrend? It seems similar.

EasyLanguage SuperTrend indicator

Here is my version of a TradeStation/MultiCharts EasyLanguage SuperTrend indicator.

I made it a function so it could be called easily from a strategy.

Function:

// SuperTrend function
// March 25 2010
// Big Mike
inputs:
ATRLength(NumericSimple), …

Mike

December 28th, 2010, 03:47 PM

No, I hadn't seen your code before posting mine, no kidding

Seriously, the idea is the same except that I use separate data streams which sometimes allow for using interesting solutions like mixing up instruments or using artificial indices, etc.

ZigZag expanded in time (code)

Discussion in EasyLanguage Programming

ZigZag expanded in time (code)