using elsystem ; 								
using elsystem.drawingobjects ; 								
using elsystem.drawing ; 								
								
inputs: 								
	BackBars(10), 							
    PtOffsetPoint(0.5), UniqueID("GGG"); 								
	 							
Vars: 								
	ii(0), ptoffset(0), TextLabel BarCounterTxt( NULL ), TextLabel DeleteText(NULL), BNPoint PosBN( NULL ); 							
	 							
Arrays: TXID[100](0);	 							
method void CreateBNLabel(int barcnt) 								
	begin 							
	{ create position for the text label by bar number using the BNPoint class } 							
	PosBN = BNPoint.Create( CurrentBar - barcnt, Low[barcnt]-PtOffsetPoint) ; 							
		 						
	{ create the text label } 							
	BarCounterTxt = TextLabel.Create( PosBN, Numtostr(barcnt+1,0) ) ; 							
	BarCounterTxt.Font = Font.Create( "Arial", 8 ) ; 							
	BarCounterTxt.HStyle = HorizontalStyle.center ; 							
	BarCounterTxt.VStyle = VerticalStyle.top;							
	BarCounterTxt.Color = Color.Red ; 							
	BarCounterTxt.Tag = UniqueID astype string ;							
		 	 					
	BarCounterTxt.Persist = true ; 							
	end ;	 						
								
method void ShowText() 								
	begin 							
		DrawingObjects.Add( BarCounterTxt ) ; 						
	end;							
//Deleting the Old Texts								
method void deleteAllText()  								
Var: int textList, int textCnt,int jj  ;  								
begin  								
    textList = ObjectCategory.TextLabel;   								
    textCnt = DrawingObjects.Items[textList].Count;  								
    if (LastBarOnChart) then   								
    begin  								
        for jj = 0 to TextCnt - 1   								
        begin  								
            DeleteText = DrawingObjects.Items[textList][jj] astype TextLabel;  								
            if (DeleteText <> NULL) and DeleteText.Tag astype string = UniqueID then DrawingObjects.Delete(DeleteText);  								
        end;  								
    end;  								
end;     								
								
	if (LastBarOnChart) and (BarStatus(1)=2) then 							
	begin 		 					
		deleteAllText();						
		for ii = 0 to BackBars -1						
		begin 						
			CreateBNLabel(ii);					
			ShowText();					
		end; 						
	end;