sell this bar, not next bar, is that possible?

August 22nd, 2012, 02:46 AM

@Bimi, could you kindly elaborate a little?

Sounds interesting but I have not caught it.

@KhaosTrader, you can use a flag. For instance a boolean AlreadyTradedThisBar that you would set to false at each new bar (BarStatus).

Nicolas

Envoy� depuis mon GT-I9100 avec Tapatalk

August 22nd, 2012, 03:40 AM

Nicolas,

I implemented your suggestion by setting the flag, EnterTrade = false.. But now it wont enter all trades it should.. Here is the screenshot....

here is the code snippet..

Code

if ( BarStatus(1) = 2 ) then begin 
	EnterTrade = ( Low >= Low[1] and High >= High[1] );
	LongEntryPrice = High;
	ShortEntryPrice = Low;
end;

if MarketPosition = 0 and EnterTrade then begin
	Buy ("Enter Long") 300 Shares next Bar at LongEntryPrice stop;
	EnterTrade = false;
	//SellShort("Enter Short") 300  Shares Next Bar at (ShortEntryPrice) stop;
end;

Here is full code:

Code

Inputs:
	Target1 (50),
  	Target2(100),
  	Target3(200),
  	StopSize(75),
  	BuyGap(.20),
  	BE2(1) , // 0=false, 1 = true
  	BE3(1); // 0=false, 1 = true
  	
 Variables:
 	EnterTrade 	( false ),
	LongEntryPrice ( 0 ),
	ShortEntryPrice ( 0 ),
   	TickSize (MinMove/PriceScale),
  	t1 (target1*TickSize),
  	t2 (target2*TickSize),
  	t3 (target3*TickSize),
  	st1 (0),
  	st2 (0),
  	st3 (0);
 

[IntrabarOrderGeneration = true]

if ( BarStatus(1) = 2 ) then begin 
	EnterTrade = ( Low >= Low[1] and High >= High[1] );
	LongEntryPrice = High;
	ShortEntryPrice = Low;
end;

if MarketPosition = 0 and EnterTrade then begin
	Buy ("Enter Long") 300 Shares next Bar at LongEntryPrice stop;
	EnterTrade = false;
	//SellShort("Enter Short") 300  Shares Next Bar at (ShortEntryPrice) stop;
end;


//Label # Shares below each bar
Value1 = Text_New(Date, Time, Low-(2), NumToStr(CurrentShares/100, 0));
Text_SetColor(Value1, Blue);
Text_SetSize(Value1, 9);


if MarketPosition = 1 then begin

 	st1 = EntryPrice - (stopsize * TickSize);
 	st2 = iff(BE2 = 1, EntryPrice, EntryPrice-(stopsize * TickSize));
 	st3 = iff(BE3 = 1, EntryPrice, EntryPrice-(stopsize * TickSize));

	if CurrentShares = 100 then begin
		Sell("Exit L300-CS100 Target") 100 Shares next Bar at (EntryPrice + t3) Limit;
		Sell("Exit L300-CS100 Stop") 100 Shares next Bar at st3 Stop;
	end;
	
	if CurrentShares = 200 then begin
   		Sell("Exit L200-CS200 Target") 100 Shares Next Bar at (EntryPrice + t2) Limit;
   		Sell("Exit L200-CS200 Stop") 100 Shares Next Bar at st2 Stop;	
   		Sell("Exit L300-CS200 Target") 100 Shares Next Bar at (EntryPrice + t3) Limit;
   		Sell("Exit L300-CS200 Stop") 100 Shares Next Bar at st3 Stop;	
   	end;
   	
   	if CurrentShares = 300 then begin
   		Sell("Exit L100-CS300 Target") 100 Shares Next Bar at (EntryPrice + t1) Limit;
   		Sell("Exit L100-CS300 Stop") 100 Shares Next Bar at st1 Stop;	
   		Sell("Exit L200-CS300 Target") 100 Shares Next Bar at (EntryPrice + t2) Limit;
   		Sell("Exit L200-CS300 Stop") 100 Shares Next Bar at st2 Stop;	
   		Sell("Exit L300-CS300 Target") 100 Shares Next Bar at (EntryPrice + t3) Limit;
   		Sell("Exit L300-CS300 Stop") 100 Shares Next Bar at st3 Stop;
   	end;
	
end;


if MarketPosition = -1 then begin

 	st1 = EntryPrice + (stopsize * TickSize);
 	st2 = iff(BE2 = 1, EntryPrice, EntryPrice+(stopsize * TickSize));
 	st3 = iff(BE3 = 1, EntryPrice, EntryPrice+(stopsize * TickSize));

	if CurrentShares = 100 then begin
		BuyToCover("Exit S300-CS100 Target") 100 Shares next Bar at (EntryPrice - t3) Limit;
		BuyToCover("Exit S300-CS100 Stop") 100 Shares next Bar at st3 Stop;
	end;
	
	if CurrentShares = 200 then begin
   		BuyToCover("Exit S200-CS200 Target") 100 Shares Next Bar at (EntryPrice - t2) Limit;
   		BuyToCover("Exit S200-CS200 Stop") 100 Shares Next Bar at st2 Stop;	
   		BuyToCover("Exit S300-CS200 Target") 100 Shares Next Bar at (EntryPrice - t3) Limit;
   		BuyToCover("Exit S300-CS200 Stop") 100 Shares Next Bar at st3 Stop;	
   	end;
   	
   	if CurrentShares = 300 then begin
   		BuyToCover("Exit S100-CS300 Target") 100 Shares Next Bar at (EntryPrice - t1) Limit;
   		BuyToCover("Exit S100-CS300 Stop") 100 Shares Next Bar at st1 Stop;	
   		BuyToCover("Exit S200-CS300 Target") 100 Shares Next Bar at (EntryPrice - t2) Limit;
   		BuyToCover("Exit S200-CS300 Stop") 100 Shares Next Bar at st2 Stop;	
   		BuyToCover("Exit S300-CS300 Target") 100 Shares Next Bar at (EntryPrice - t3) Limit;
   		BuyToCover("Exit S300-CS300 Stop") 100 Shares Next Bar at st3 Stop;
   	end;
	
end;

August 22nd, 2012, 03:43 AM

Oh on the Strategy, I set the following:

* Allow unlimited entries per bar

* Backtesting Precision : Use Bar Magnifier [checked], Intraday=1 minutes, Skip ticks with identical prices [checked]

August 22nd, 2012, 03:48 AM

Seems logical...

I copy your code:

Quoting

if ( BarStatus(1) = 2 ) then begin
EnterTrade = ( Low >= Low[1] and High >= High[1] );
LongEntryPrice = High;
ShortEntryPrice = Low;
end;

if MarketPosition = 0 and EnterTrade then begin
Buy ("Enter Long") 300 Shares next Bar at LongEntryPrice stop;
EnterTrade = false;
//SellShort("Enter Short") 300 Shares Next Bar at (ShortEntryPrice) stop;
end;

Let's suppose that, at the last tick of the bar (BarStatus = 2), EnterTrade is set to true (first part of the code)
With the 2nd part of the code, you ask to buy at the next tick (first tick of the next bar) at a given price.
But you also set EnterTrade to false.
So, if the given price is not reached on the first tick of the next bar, the code will not enter trade later within the bar.

Nicolas

August 22nd, 2012, 03:56 AM

I see your point....

I then moved the "EnterTrade = false;" to the "if marketposition =1 then begin...

Code

if MarketPosition = 1 then begin
	EnterTrade = false;
 	st1 = EntryPrice - (stopsize * TickSize);
 	st2 = iff(BE2 = 1, EntryPrice, EntryPrice-(stopsize * TickSize));
 	st3 = iff(BE3 = 1, EntryPrice, EntryPrice-(stopsize * TickSize));

	if CurrentShares = 100 then begin
		Sell("Exit L300-CS100 Target") 100 Shares next Bar at (EntryPrice + t3) Limit;
		Sell("Exit L300-CS100 Stop") 100 Shares next Bar at st3 Stop;
	end;

but now again, it enters multiple times each bar... So I am pretty much at a loss on what to do...

August 22nd, 2012, 04:52 AM

@KhaosTrader,

Could you test the 2 following modifications?

(1) In the Variables declaration, add one intrabarpersist:

Code

intrabarpersist EnterLong	( false ),

(2) At the beginning of "if MarketPosition = 1", add one line:

Code

if MarketPosition = 1 then begin
   EnterLong = false;
   [...]

--> Seems OK on my side (one entry per bar).

If it "doesn't work" on your side, please post again the whole code and a snapshot showing the problem.

I have to be frank: due to time constraints, I am not sure I will be able to continue here.

Nicolas

August 22nd, 2012, 09:32 AM

I think its working

I will test it more...

How did you discover the intrabarpersist ?

Thanks Nicolas!

August 22nd, 2012, 09:34 AM

I'm happy it seems to work.

"How did you discover the intrabarpersist ?"
It is a secret.

Nicolas

August 22nd, 2012, 09:38 AM

LOL well, you are really good at easylanguage, I doubt I would have found that.

Thanks

sell this bar, not next bar, is that possible?

Discussion in EasyLanguage Programming

sell this bar, not next bar, is that possible?