True Strength Indicator/Easy Language programming problem

January 5th, 2012, 12:23 PM

Try this:

eseeker

First: Create the Function TSI:

Code


 // Function: TSI
  [LegacyColorValue = true];
  inputs:  	Price(NumericSeries),  	Raw(NumericSimple),  	Smooth(NumericSimple), 	U(NumericSimple);
  vars:  	NetChg(0);  	NetChg = Price - Price[1];
  Value1 = 100 * XAverage(XAverage(XAverage(NetChg,Raw),Smooth),U);
  Value2 = XAverage(XAverage(XAverage(AbsValue(NetChg),Raw),Smooth),U);
  if Value2 <> 0 then 	TSI = Value1 / Value2 else 	TSI = 0;

-> Save as: TSI
--> Compile Function

eseeker

Then create the TSI indicator.

Code


 // Indicator: TSI
  [LegacyColorValue = true];
  [SameTickOpt = True];
  inputs:  	Price(Close),  	Raw(26),  	Smoothed(12), 	Signal(5), 	OB(20), 	OS(-20);
  Plot1(TSI(Price, Raw, Smoothed,1), "TSI");
  Plot2(XAverage(Plot1,signal),"XAvg ");
  Plot3(OB,"Overbought");
  Plot4(OS,"Oversold");

--> Compile Indicator

January 5th, 2012, 08:24 PM

I copied that exact 2 programs as mentioned above,and this is what I got:
The formula posted like this:
1#indicator "True Strength Indes", "Samples", "TSISample"
2
3// Function: TSI
4
5
6inputs:
7 Price(NumericSeries),
8 Raw(NumericSimple),
9 Smooth(NumericSimple),
10 U(NumericSimple);
11
12vars:
13 NetChg(0);
14
15 NetChg = Price - Price[1];
16
17Value1 = 100 * XAverage(XAverage(XAverage(NetChg,Raw),Smooth),U);
18Value2 = XAverage(XAverage(XAverage(AbsValue(NetChg),Raw),Smooth),U);
19
20if Value2 <> 0 then
21 TSI = Value1 / Value2
22else
23 TSI = 0;
24
25
26// Indicator: TSI
27
28
29{[SameTickOpt = True];}
30
31inputs:
32 Price(Close),
33 Raw(26),
34 Smoothed(12),
35 Signal(5),
36 OB(20),
37 OS(-20);
38
39Plot1(TSI(Price, Raw, Smoothed,1), "TSI");
40Plot2(XAverage(Plot1,signal),"XAvg ");
41Plot3(OB,"Overbought");
42Plot4(OS,"Oversold");

Compile Errors were:
21 Unknown symbol: TSI
21 Wrong sybmbol on left side: TSI
23 Unknown symbol: TSI
23 Wrong sybmbol on left side: TSI
32 Variable 'Price" is already defined
33 Variable 'Raw" is already defined
39 Unknown symbol: TSI
22 Cannot compile: True Strength Ind

I deleted the references to color.

January 5th, 2012, 08:30 PM

No.

Do the function first. Stop. Save. Compile.

Then new indicator. Stop. Save. Compile.

You've put them all together, they are separate.

Mike

January 5th, 2012, 10:19 PM

I thank you both for your advice.
I followed your directions.

The first portion compiled fine and was saved as TSI.el

The second portion gave me eleven errors on the compile.

17 #function [SameTickOpt
18 // Indicator: TSI
19 [LegacyColorValue = true];
20 [SameTickOpt = True];
21 inputs: Price(Close), Raw(26), Smoothed(12), Signal(5), OB(20), OS(-20);
22 Plot1(TSI(Price, Raw, Smoothed,1), "TSI");
23 Plot2(XAverage(Plot1,signal),"XAvg ");
24 Plot3(OB,"Overbought");
25 Plot4(OS,"Oversold");

Errors
19 Syntax erro. "=" expected
17 Misused attribute unknown
19 Unsupported attribute
20(2) Unk attrib.; misused attri.
22-25 Plotting functions are not allowed.
18 Can't compile: TSI

Any ideas?
Thanks again.

January 6th, 2012, 12:07 AM

Use this format to make this indicator work on the OEC platform. The function needs to be included in the actual indicator file.

Code

#indicator "True Strength Indes", "Samples", "TSISample"

// Indicator: TSI


{[SameTickOpt = True];}

inputs: 
 Price(Close), 
 Raw(26), 
 Smoothed(12),
 Signal(5),
 OB(20),
 OS(-20);

Plot1(TSI(Price, Raw, Smoothed,1), "TSI");
Plot2(XAverage(Plot1,signal),"XAvg ");
Plot3(OB,"Overbought");
Plot4(OS,"Oversold");

// Function: TSI

#function TSI
inputs: 
 Price(NumericSeries), 
 Raw(NumericSimple), 
 Smooth(NumericSimple),
 U(NumericSimple);
 
vars: 
 NetChg(0);

 NetChg = Price - Price[1];

Value1 = 100 * XAverage(XAverage(XAverage(NetChg,Raw),Smooth),U);
Value2 = XAverage(XAverage(XAverage(AbsValue(NetChg),Raw),Smooth),U);

if Value2 <> 0 then
 TSI = Value1 / Value2
else
 TSI = 0;

January 6th, 2012, 11:23 AM

HOORAH

I think the last one may be working.\
Many thanks,

I'll let you know what happens.
Dick

August 1st, 2012, 04:39 PM

I'm a newbie in tradestation and I don't know how to compile a function. Can you explain me?

Thanks

August 1st, 2012, 06:43 PM

jguellbo

I'm a newbie in tradestation and I don't know how to compile a function. Can you explain me?

Thanks

When you compile a function, you're simply creating a file with a series of calculations that is named as the function word/name. That way, you can simply reference that group/function in other files such as indicators and strategies, without having to include all the language.

Once you copy/paste the language into a new function you opened, you simply click on the green check icon. If it's error free, it will turn neutral color and save it and give you no errors or warnings at the bottom of the EL program.

Only then can other indicators and strategies that are written with this function in them know what you're trying to refer to in the language.

August 2nd, 2012, 12:16 PM

Thank you RM99, that's very kind of you.

True Strength Indicator/Easy Language programming problem

Discussion in EasyLanguage Programming

True Strength Indicator/Easy Language programming problem