How to plot the previous 20 period RSI(9) high overlay on current RSI(9)?

February 22nd, 2016, 04:16 AM

Hello guys,

i am beginner to Amibroker and will appreciate much if you can teach me how to write the code for this conditions:

How to plot the previous 20 period Highest RSI(9) high overlay on current RSI(9)?

Thank you!

February 22nd, 2016, 02:33 PM

See https://www.amibroker.com/guide/afl/hhv.html

Code

// RSI and HHV(RSI) example
// by prouser

SetChartOptions( 0, chartShowArrows | chartShowDates | chartWrapTitle, gridFlags = 0, ymax = 0, xmax = 0, blankmargin = 0 );

periods = Param( "RSI Periods", 15, 1, 200, 1 );
HHVperiods = Param( "HHV Periods", 20, 1, 200, 1 );
RSIcolor = ParamColor( "RSI Color", colorCycle );

myRSI = RSI( periods );
HHV_RSI = HHV( myRSI, HHVperiods );

GraphLabelDecimals = 2;

Plot( myRSI, "RSI", RSIcolor, ParamStyle( "RSI Style" ) | styleNoTitle, Null, Null, 0, 1 );
Plot( HHV_RSI, "HHV RSI", colorDarkGreen, ParamStyle( "HHV Style" ) | styleNoTitle, Null, Null, 0, 1 );

PlotGrid( 30, colorBrightGreen, pattern = 0, width = 2, label = True );
PlotGrid( 50, colorGrey50, pattern, width, label );
PlotGrid( 70, colorRed, pattern, width, label );

_N( Title = StrFormat( "{{NAME}} - {{INTERVAL}} - " +
                       EncodeColor( RSIcolor ) + "RSI(%g): %g  " +
                       EncodeColor( colorDarkGreen ) + "HHV(RSI(%g), %g): %g " +
                       EncodeColor( -1 ) + "{{VALUES}}",
                       periods, myRSI, periods, hhvperiods, HHV_RSI ) );

February 22nd, 2016, 06:06 PM

Thank you so much Prouser, this is what i am trying to plot. =)
Will let you know if i manage to get any meaningful results from it.

Have a great week!

February 22nd, 2016, 07:47 PM

Hi, so sorry to bother again.

I am trying to issue a buy signal when the RSI(x) becomes the HHV_RSI, plus only when RSI is more than 50 but unable to get a accurate buy signal from my backtest. The buy signals are random not following the criteria i issue.
Here is the code i used. Is there any mistake here?

BuySignal1 = Cross(myRSI, HHV_RSI); // myRSI >= HHV_RSI;
BuySignal2 = myRSI > 50;

// buy on the next bar
Buy = Ref( BuySignal1 AND BuySignal2, -1);

TY

February 23rd, 2016, 07:40 AM

If you use Cross() then you expect one var to have a higher/lower value than the second var in order to return true.
So in this case you expect RSI of "current" bar having a higher value than its own highest value at "current" bar. If a var crosses above its own "current" highest value then it would be expected to be higher than that. But it is logically impossible that this condition will ever return true. Can you follow the logic?

That's why using previous highest value as second argument would make more sense.

Code

BuySignal1 = Cross( myRSI, Ref(HHV_RSI, -1) );

February 23rd, 2016, 11:48 AM

Thanks prouser. I understand the logic now. Basically the two period moves systematically so it doesnt make sense for it to cross over its own high. It makes more sense with a 1 bar delay like the one in your code.

Thanks for clearing my doubts again=)

How to plot the previous 20 period RSI(9) high overlay on current RSI(9)?

Discussion in Platforms and Indicators

How to plot the previous 20 period RSI(9) high overlay on current RSI(9)?